mirror of
https://git.yoctoproject.org/poky
synced 2026-04-26 00:32:12 +02:00
012a572e86
Upgrade shadow from 4.1.4.3 to 4.2.1. Changes during this upgrade are as following. 1. Remove the "merged" patches. These patches are either merged or the same functionality has been implemented upstream. add_root_cmd_groupmems.patch add_root_cmd_options.patch fix-etc-gshadow-reading.patch shadow-4.1.4.2-env-reset-keep-locale.patch shadow-4.1.4.2-groupmod-pam-check.patch shadow-4.1.4.2-su_no_sanitize_env.patch shadow.automake-1.11.patch shadow_fix_for_automake-1.12.patch useradd.patch 2. Remove the unneeded patch. The following patch has been removed because the logic in the related codes of the new version has been changed. In specific, the codes now can handle the 'NULL' return value. So there's no need for the following patch. slackware_fix_for_glib-2.17_crypt.patch 3. Teak the current patch to match the new version. allow-for-setting-password-in-clear-text.patch 4. Add a patch to fix compilation failure. usermod-fix-compilation-failure-with-subids-disabled.patch 5. Add a patch to fix the installation failure. fix-installation-failure-with-subids-disabled.patch 5. Add a patch to fix the failure at rootfs time if extrausers is inherited. commonio.c-fix-unexpected-open-failure-in-chroot-env.patch 6. Fix the bad section in the recipe. 7. Disable the new subids feature in the new version as it doesn't support cross compilation for now. 8. Modify the pkg_postinst to `exit 1' if the `pwconv' or `grpconv' fails. Also, fix the arguments to use '--root $D' instead of '--root=$D'. 9. Add a patch for shadow-native to create parent directories when necessary. 0001-useradd.c-create-parent-directories-when-necessary.patch (From OE-Core rev: b73e5cd51551556f9e6a4f7d9e7deec4d9d661bd) Signed-off-by: Chen Qi <Qi.Chen@windriver.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
37 lines
1.2 KiB
BlitzBasic
37 lines
1.2 KiB
BlitzBasic
SUMMARY = "Provider of the machine specific securetty file"
|
|
SECTION = "base utils"
|
|
LICENSE = "MIT"
|
|
LIC_FILES_CHKSUM = "file://${COREBASE}/meta/COPYING.MIT;md5=3da9cfbcb788c80a0384361b4de20420"
|
|
|
|
INHIBIT_DEFAULT_DEPS = "1"
|
|
|
|
PR = "r3"
|
|
|
|
SRC_URI = "file://securetty"
|
|
|
|
# Since SERIAL_CONSOLES is likely to be set from the machine configuration
|
|
PACKAGE_ARCH = "${MACHINE_ARCH}"
|
|
|
|
do_install () {
|
|
# Ensure we add a suitable securetty file to the package that has
|
|
# most common embedded TTYs defined.
|
|
install -d ${D}${sysconfdir}
|
|
install -m 0400 ${WORKDIR}/securetty ${D}${sysconfdir}/securetty
|
|
if [ ! -z "${SERIAL_CONSOLES}" ]; then
|
|
# Our SERIAL_CONSOLES contains a baud rate and sometimes extra
|
|
# options as well. The following pearl :) takes that and converts
|
|
# it into newline-separated tty's and appends them into
|
|
# securetty. So if a machine has a weird looking console device
|
|
# node (e.g. ttyAMA0) that securetty does not know, it will get
|
|
# appended to securetty and root logins will be allowed on that
|
|
# console.
|
|
tmp="${SERIAL_CONSOLES}"
|
|
for entry in $tmp ; do
|
|
ttydev=`echo "$entry" | sed -e 's/^[0-9]*\;//' -e 's/\;.*//'`
|
|
if ! grep -q $ttydev ${D}${sysconfdir}/securetty; then
|
|
echo $ttydev >> ${D}${sysconfdir}/securetty
|
|
fi
|
|
done
|
|
fi
|
|
}
|