mirror of
https://git.yoctoproject.org/poky
synced 2026-09-29 07:36:20 +02:00
9916b7471e
glibc-testsuite does not run on target or factor into the build supply chain, since its purpose is run tests in Qemu at build time (From OE-Core rev: 3217490cc554069ae53aa54cf8ad7327ce85fa10) Signed-off-by: Joshua Watt <JPEWhacker@gmail.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org> (cherry picked from commit 32801348ca231978498612f3ebee121ca27459c1) [YC: See https://lore.kernel.org/all/20260708115052.71740-1-jaipaul.cheernam@est.tech/ ] Signed-off-by: Yoann Congal <yoann.congal@smile.fr> Signed-off-by: Paul Barker <paul@pbarker.dev>
38 lines
962 B
BlitzBasic
38 lines
962 B
BlitzBasic
require glibc_${PV}.bb
|
|
require glibc-tests.inc
|
|
|
|
inherit qemu
|
|
|
|
SRC_URI += "file://check-test-wrapper"
|
|
|
|
# strip provides
|
|
PROVIDES = ""
|
|
|
|
DEPENDS += "${@'qemu-native' if d.getVar('TOOLCHAIN_TEST_TARGET') == 'user' else ''}"
|
|
|
|
TOOLCHAIN_TEST_TARGET ??= "user"
|
|
TOOLCHAIN_TEST_HOST ??= "localhost"
|
|
TOOLCHAIN_TEST_HOST_USER ??= "root"
|
|
TOOLCHAIN_TEST_HOST_PORT ??= "2222"
|
|
|
|
do_check[nostamp] = "1"
|
|
do_check[network] = "1"
|
|
do_check:append () {
|
|
chmod 0755 ${WORKDIR}/check-test-wrapper
|
|
|
|
oe_runmake -i \
|
|
QEMU_SYSROOT="${RECIPE_SYSROOT}" \
|
|
QEMU_OPTIONS="${@qemu_target_binary(d)} ${QEMU_OPTIONS}" \
|
|
SSH_HOST="${TOOLCHAIN_TEST_HOST}" \
|
|
SSH_HOST_USER="${TOOLCHAIN_TEST_HOST_USER}" \
|
|
SSH_HOST_PORT="${TOOLCHAIN_TEST_HOST_PORT}" \
|
|
test-wrapper="${WORKDIR}/check-test-wrapper ${TOOLCHAIN_TEST_TARGET}" \
|
|
check
|
|
}
|
|
|
|
inherit nopackages
|
|
inherit nospdx
|
|
deltask do_stash_locale
|
|
deltask do_install
|
|
deltask do_populate_sysroot
|