mirror of
https://git.yoctoproject.org/poky
synced 2026-02-26 03:19:41 +01:00
ba2f6c64a1
Github has announced there will be no more git:// fetching from their servers: https://github.blog/2021-09-01-improving-git-protocol-security-github/#no-more-unauthenticated-git and they're about to start having brownout periods to encourage people to update. This runs the conversion script over OE-Core to update our urls to use https instead of git. (From OE-Core rev: b37b61e9a1e448a34957db9ae39285d21352552e) Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
59 lines
2.0 KiB
BlitzBasic
59 lines
2.0 KiB
BlitzBasic
SUMMARY = "interface to seccomp filtering mechanism"
|
|
DESCRIPTION = "The libseccomp library provides and easy to use, platform independent,interface to the Linux Kernel's syscall filtering mechanism: seccomp."
|
|
HOMEPAGE = "https://github.com/seccomp/libseccomp"
|
|
SECTION = "security"
|
|
LICENSE = "LGPL-2.1"
|
|
LIC_FILES_CHKSUM = "file://LICENSE;beginline=0;endline=1;md5=8eac08d22113880357ceb8e7c37f989f"
|
|
|
|
DEPENDS += "gperf-native"
|
|
|
|
PV .= "+git${SRCPV}"
|
|
SRCREV = "2457dec1a90101d720e89e8027376742e2f3c327"
|
|
|
|
SRC_URI = "git://github.com/seccomp/libseccomp.git;branch=main;protocol=https \
|
|
file://0001-configure.ac-Bump-version-to-2.5.99.patch \
|
|
file://0001-arch-Add-riscv32-architecture-support.patch \
|
|
file://0002-man-Add-RISCV64-to-arch-list.patch \
|
|
file://0003-syscalls-update-the-syscall-defs-for-Linux-v5.15.0-r.patch \
|
|
file://0004-syscalls-Add-quotactl_path.patch \
|
|
file://run-ptest \
|
|
"
|
|
|
|
S = "${WORKDIR}/git"
|
|
|
|
inherit autotools-brokensep pkgconfig ptest features_check
|
|
|
|
REQUIRED_DISTRO_FEATURES = "seccomp"
|
|
|
|
PACKAGECONFIG ??= ""
|
|
PACKAGECONFIG[python] = "--enable-python, --disable-python, python3"
|
|
|
|
DISABLE_STATIC = ""
|
|
|
|
do_compile_ptest() {
|
|
oe_runmake -C tests check-build
|
|
}
|
|
|
|
do_install_ptest() {
|
|
install -d ${D}${PTEST_PATH}/tests
|
|
install -d ${D}${PTEST_PATH}/tools
|
|
for file in $(find tests/* -executable -type f); do
|
|
install -m 744 ${S}/${file} ${D}/${PTEST_PATH}/tests
|
|
done
|
|
for file in $(find tests/*.tests -type f); do
|
|
install -m 744 ${S}/${file} ${D}/${PTEST_PATH}/tests
|
|
done
|
|
for file in $(find tools/* -executable -type f); do
|
|
install -m 744 ${S}/${file} ${D}/${PTEST_PATH}/tools
|
|
done
|
|
# Overwrite libtool wrappers with real executables
|
|
for file in $(find tools/.libs/* -executable -type f); do
|
|
install -m 744 ${S}/${file} ${D}/${PTEST_PATH}/tools
|
|
done
|
|
}
|
|
|
|
FILES:${PN} = "${bindir} ${libdir}/${BPN}.so*"
|
|
FILES:${PN}-dbg += "${libdir}/${PN}/tests/.debug/* ${libdir}/${PN}/tools/.debug"
|
|
|
|
RDEPENDS:${PN}-ptest = "coreutils bash"
|