mirror of
https://git.yoctoproject.org/poky
synced 2026-04-24 21:32:12 +02:00
2346c7ca09
* use virtual/* variables as INHIBIT_DEFAULT_DEPS does to avoid dependency on gcc-cross- from nativesdk-libgfortran * the dependency was added in: https://git.openembedded.org/openembedded-core/commit/?id=00fba52c8a6f6383137cf89fc7aa34cc3e2ff45f causing: build/oe-core $ bitbake -g nativesdk-libgfortran NOTE: Resolving any missing task queue dependencies ERROR: Nothing PROVIDES 'gcc-cross-x86_64' (but virtual:nativesdk:/OE/build/oe-core/openembedded-core/meta/recipes-devtools/gcc/libgfortran_14.1.bb DEPENDS on or otherwise requires it). Close matches: gcc-cross-aarch64 ... with: MACHINE=qemuarm64 FORTRAN:forcevariable = ",fortran" * after: https://git.openembedded.org/openembedded-core/commit/?id=44fc7aa1468ff042739cc5a91c84ef5c2a09e0a3 nativesdk-libgfortran is pulled as dependency of nativesdk-gcc so this affects more people who didn't explicitly use nativesdk-libgfortran before * the INHIBIT_DEFAULT_DEPS and gcc-runtime was there since gcc-4.8: https://git.openembedded.org/openembedded-core/commit/?id=a5e7ee5770b9e0cf719c573efffd874440f74289 (From OE-Core rev: 5ce2e9c66cd2c08e141913ec65386f940353a8c5) Signed-off-by: Martin Jansa <martin.jansa@gmail.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
90 lines
2.8 KiB
PHP
90 lines
2.8 KiB
PHP
require gcc-configure-common.inc
|
|
|
|
EXTRA_OECONF_PATHS = "\
|
|
--with-sysroot=/not/exist \
|
|
--with-build-sysroot=${STAGING_DIR_TARGET} \
|
|
"
|
|
|
|
# An arm hard float target like raspberrypi4 won't build
|
|
# as CFLAGS don't make it to the fortran compiler otherwise
|
|
# (the configure script sets FC to $GFORTRAN unconditionally)
|
|
export GFORTRAN = "${FC}"
|
|
|
|
do_configure () {
|
|
for target in libbacktrace libgfortran
|
|
do
|
|
rm -rf ${B}/${TARGET_SYS}/$target/
|
|
mkdir -p ${B}/${TARGET_SYS}/$target/
|
|
cd ${B}/${TARGET_SYS}/$target/
|
|
chmod a+x ${S}/$target/configure
|
|
relpath=${@os.path.relpath("${S}", "${B}/${TARGET_SYS}")}
|
|
../$relpath/$target/configure ${CONFIGUREOPTS} ${EXTRA_OECONF}
|
|
# Easiest way to stop bad RPATHs getting into the library since we have a
|
|
# broken libtool here
|
|
sed -i -e 's/hardcode_into_libs=yes/hardcode_into_libs=no/' ${B}/${TARGET_SYS}/$target/libtool
|
|
done
|
|
}
|
|
EXTRACONFFUNCS += "extract_stashed_builddir"
|
|
do_configure[depends] += "${COMPILERDEP}"
|
|
|
|
do_compile () {
|
|
for target in libbacktrace libgfortran
|
|
do
|
|
cd ${B}/${TARGET_SYS}/$target/
|
|
oe_runmake MULTIBUILDTOP=${B}/${TARGET_SYS}/$target/
|
|
done
|
|
}
|
|
|
|
do_install () {
|
|
cd ${B}/${TARGET_SYS}/libgfortran/
|
|
oe_runmake 'DESTDIR=${D}' MULTIBUILDTOP=${B}/${TARGET_SYS}/libgfortran/ install
|
|
if [ -d ${D}${libdir}/gcc/${TARGET_SYS}/${BINV}/finclude ]; then
|
|
rmdir --ignore-fail-on-non-empty -p ${D}${libdir}/gcc/${TARGET_SYS}/${BINV}/finclude
|
|
fi
|
|
if [ -d ${D}${infodir} ]; then
|
|
rmdir --ignore-fail-on-non-empty -p ${D}${infodir}
|
|
fi
|
|
chown -R root:root ${D}
|
|
}
|
|
|
|
# avoid virtual/libc
|
|
INHIBIT_DEFAULT_DEPS = "1"
|
|
DEPENDS = "virtual/${HOST_PREFIX}gcc virtual/${HOST_PREFIX}compilerlibs"
|
|
|
|
BBCLASSEXTEND = "nativesdk"
|
|
|
|
PACKAGES = "\
|
|
${PN}-dbg \
|
|
libgfortran \
|
|
libgfortran-dev \
|
|
libgfortran-staticdev \
|
|
"
|
|
|
|
LICENSE:${PN} = "GPL-3.0-with-GCC-exception"
|
|
LICENSE:${PN}-dev = "GPL-3.0-with-GCC-exception"
|
|
LICENSE:${PN}-dbg = "GPL-3.0-with-GCC-exception"
|
|
|
|
FILES:${PN} = "${libdir}/libgfortran.so.*"
|
|
FILES:${PN}-dev = "\
|
|
${libdir}/libgfortran*.so \
|
|
${libdir}/libgfortran.spec \
|
|
${libdir}/libgfortran.la \
|
|
${libdir}/gcc/${TARGET_SYS}/${BINV}/libgfortranbegin.* \
|
|
${libdir}/gcc/${TARGET_SYS}/${BINV}/libcaf_single* \
|
|
${libdir}/gcc/${TARGET_SYS}/${BINV}/finclude/ \
|
|
${libdir}/gcc/${TARGET_SYS}/${BINV}/include/ \
|
|
"
|
|
FILES:${PN}-staticdev = "${libdir}/libgfortran.a"
|
|
|
|
INSANE_SKIP:${MLPREFIX}libgfortran-dev = "staticdev"
|
|
|
|
do_package_write_ipk[depends] += "virtual/${MLPREFIX}libc:do_packagedata"
|
|
do_package_write_deb[depends] += "virtual/${MLPREFIX}libc:do_packagedata"
|
|
do_package_write_rpm[depends] += "virtual/${MLPREFIX}libc:do_packagedata"
|
|
|
|
python __anonymous () {
|
|
f = d.getVar("FORTRAN")
|
|
if "fortran" not in f:
|
|
raise bb.parse.SkipRecipe("libgfortran needs fortran support to be enabled in the compiler")
|
|
}
|