mirror of
https://git.yoctoproject.org/poky
synced 2026-04-25 15:32:13 +02:00
0d0cf152a9
Release notes: * Feature: support for rx-flow-hash gtp (-N) * Feature: support for RSS input transformation (-X) * Fix: typo in coalescing output (-c) * Fix: document all debugging flags in man page (From OE-Core rev: 302bbd0fdb1b41ec98e281cacbb77a54ce8d689d) Signed-off-by: Changhyeok Bae <changhyeok.bae@gmail.com> Signed-off-by: Alexandre Belloni <alexandre.belloni@bootlin.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
38 lines
1.4 KiB
BlitzBasic
38 lines
1.4 KiB
BlitzBasic
SUMMARY = "Display or change ethernet card settings"
|
|
DESCRIPTION = "A small utility for examining and tuning the settings of your ethernet-based network interfaces."
|
|
HOMEPAGE = "http://www.kernel.org/pub/software/network/ethtool/"
|
|
SECTION = "console/network"
|
|
LICENSE = "GPL-2.0-or-later"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=b234ee4d69f5fce4486a80fdaf4a4263 \
|
|
file://ethtool.c;beginline=4;endline=17;md5=c19b30548c582577fc6b443626fc1216"
|
|
|
|
SRC_URI = "${KERNELORG_MIRROR}/software/network/ethtool/ethtool-${PV}.tar.gz \
|
|
file://run-ptest \
|
|
file://avoid_parallel_tests.patch \
|
|
"
|
|
|
|
SRC_URI[sha256sum] = "0011fb1b20101879f2d01d39cd2bc1d9646990d07d64de893415404a3afc53ef"
|
|
|
|
UPSTREAM_CHECK_URI = "https://www.kernel.org/pub/software/network/ethtool/"
|
|
|
|
inherit autotools ptest bash-completion pkgconfig
|
|
|
|
RDEPENDS:${PN}-ptest += "make bash"
|
|
|
|
PACKAGECONFIG ?= "netlink"
|
|
PACKAGECONFIG[netlink] = "--enable-netlink,--disable-netlink,libmnl,"
|
|
|
|
do_compile_ptest() {
|
|
oe_runmake buildtest-TESTS
|
|
}
|
|
|
|
do_install_ptest () {
|
|
cp ${B}/Makefile ${D}${PTEST_PATH}
|
|
install ${B}/test-cmdline ${D}${PTEST_PATH}
|
|
if ${@bb.utils.contains('PACKAGECONFIG', 'netlink', 'false', 'true', d)}; then
|
|
install ${B}/test-features ${D}${PTEST_PATH}
|
|
fi
|
|
install ${B}/ethtool ${D}${PTEST_PATH}/ethtool
|
|
sed -i 's/^Makefile/_Makefile/' ${D}${PTEST_PATH}/Makefile
|
|
}
|