mirror of
https://git.yoctoproject.org/poky
synced 2026-04-29 00:32:14 +02:00
b74d2ea2cc
Changelog: ============ ### Changes - Add reload command for systemd service - Add global log rotation options to .conf file, issue #80. Introducing two new settings: 'rotate_size SIZE' and 'rotate_count COUNT' - Semantic change for per-file log rotation settings, no longer possible to disable log rotation for a file by setting 'rotate=0:0' - Possible to set only size or count rotation per file - Add support for 'listen addr:port' to .conf file, issue #83 ### Fixes - Fix #72: loss of raw kernel log messages to console. - Fix #81: blocking delay for unreachable remote log server. - Fix #82: retry creating UNIX and network sockets on failure. (From OE-Core rev: 1af9b2e990f06367accb37f650223607f4442409) Signed-off-by: Wang Mingyu <wangmy@fujitsu.com> Signed-off-by: Alexandre Belloni <alexandre.belloni@bootlin.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
57 lines
1.7 KiB
BlitzBasic
57 lines
1.7 KiB
BlitzBasic
SUMMARY = "System Log Daemons"
|
|
DESCRIPTION = "The sysklogd package implements system log daemons: syslogd"
|
|
HOMEPAGE = "http://www.infodrom.org/projects/sysklogd/"
|
|
SECTION = "base"
|
|
|
|
LICENSE = "BSD-3-Clause"
|
|
LIC_FILES_CHKSUM = "file://LICENSE;md5=5b4be4b2549338526758ef479c040943 \
|
|
file://src/syslogd.c;beginline=2;endline=15;md5=a880fecbc04503f071c494a9c0dd4f97 \
|
|
"
|
|
|
|
inherit update-rc.d update-alternatives systemd autotools
|
|
|
|
SRC_URI = "git://github.com/troglobit/sysklogd.git;branch=master;protocol=https \
|
|
file://sysklogd \
|
|
"
|
|
|
|
SRCREV = "6b44b9822e8551114e1ed38c38c51b8e95188599"
|
|
|
|
S = "${WORKDIR}/git"
|
|
|
|
EXTRA_OECONF = "--with-systemd=${systemd_system_unitdir} --without-logger"
|
|
|
|
do_install:append () {
|
|
install -d ${D}${sysconfdir}
|
|
install -m 644 ${S}/syslog.conf ${D}${sysconfdir}/syslog.conf
|
|
install -d ${D}${sysconfdir}/init.d
|
|
install -m 755 ${UNPACKDIR}/sysklogd ${D}${sysconfdir}/init.d/syslog
|
|
}
|
|
|
|
SYSTEMD_PACKAGES = "${PN}"
|
|
SYSTEMD_SERVICE:${PN} = "syslogd.service"
|
|
SYSTEMD_AUTO_ENABLE = "enable"
|
|
|
|
INITSCRIPT_NAME = "syslog"
|
|
CONFFILES:${PN} = "${sysconfdir}/syslog.conf"
|
|
RCONFLICTS:${PN} = "rsyslog busybox-syslog syslog-ng"
|
|
|
|
FILES:${PN} += "${@bb.utils.contains('DISTRO_FEATURES','systemd','${exec_prefix}/lib/tmpfiles.d/sysklogd.conf', '', d)}"
|
|
|
|
ALTERNATIVE_PRIORITY = "100"
|
|
|
|
ALTERNATIVE:${PN}-doc = "syslogd.8"
|
|
ALTERNATIVE_LINK_NAME[syslogd.8] = "${mandir}/man8/syslogd.8"
|
|
|
|
pkg_prerm:${PN} () {
|
|
if test "x$D" = "x"; then
|
|
if test "$1" = "upgrade" -o "$1" = "remove"; then
|
|
/etc/init.d/syslog stop || :
|
|
fi
|
|
fi
|
|
}
|
|
|
|
python () {
|
|
if not bb.utils.contains('DISTRO_FEATURES', 'sysvinit', True, False, d):
|
|
d.setVar("INHIBIT_UPDATERCD_BBCLASS", "1")
|
|
}
|