mirror of
https://git.yoctoproject.org/poky
synced 2026-04-27 12:32:13 +02:00
6911d1f7af
After util-linux upgrade to 2.40.1, we got the following QA issue
on musl:
WARNING: libssh2-1.11.0-r0 do_package_qa: QA Issue: libssh2-ptest
rdepends on util-linux-col, but it isn't a build dependency? [build-deps]
The issue appeared because new version util-linux has disabled
building out col on musl[1]. In short, the reason is that col in
util-linux requires something that musl does not provide.
This 'util-linux-col' dependency was added in 2021, at that time
the libssh2's version is 1.9.0. Now the version is 1.11.0 and I tested
its ptest, it does not require util-linux-col to succeed.
[1] 8886d84e25
(From OE-Core rev: 9007de7e388e269028c7c1722f0d7ee76bc5d251)
Signed-off-by: Chen Qi <Qi.Chen@windriver.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
54 lines
1.7 KiB
BlitzBasic
54 lines
1.7 KiB
BlitzBasic
SUMMARY = "A client-side C library implementing the SSH2 protocol"
|
|
HOMEPAGE = "http://www.libssh2.org/"
|
|
SECTION = "libs"
|
|
|
|
DEPENDS = "zlib"
|
|
|
|
LICENSE = "BSD-3-Clause"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=24a33237426720395ebb1dd1349ca225"
|
|
|
|
SRC_URI = "http://www.libssh2.org/download/${BP}.tar.gz \
|
|
file://run-ptest \
|
|
file://CVE-2023-48795.patch \
|
|
"
|
|
|
|
SRC_URI[sha256sum] = "3736161e41e2693324deb38c26cfdc3efe6209d634ba4258db1cecff6a5ad461"
|
|
|
|
inherit autotools pkgconfig ptest
|
|
|
|
EXTRA_OECONF += "\
|
|
--with-libz \
|
|
--with-libz-prefix=${STAGING_LIBDIR} \
|
|
--disable-rpath \
|
|
"
|
|
DISABLE_STATIC = ""
|
|
|
|
# only one of openssl and gcrypt could be set
|
|
PACKAGECONFIG ??= "openssl"
|
|
PACKAGECONFIG[openssl] = "--with-crypto=openssl --with-libssl-prefix=${STAGING_LIBDIR}, , openssl"
|
|
PACKAGECONFIG[gcrypt] = "--with-crypto=libgcrypt --with-libgcrypt-prefix=${STAGING_EXECPREFIXDIR}, , libgcrypt"
|
|
|
|
BBCLASSEXTEND = "native nativesdk"
|
|
|
|
# required for ptest on documentation
|
|
RDEPENDS:${PN}-ptest = "bash man-db openssh"
|
|
RDEPENDS:${PN}-ptest:append:libc-glibc = " locale-base-en-us"
|
|
|
|
do_compile_ptest() {
|
|
sed -i "/\$(MAKE) \$(AM_MAKEFLAGS) check-TESTS/d" tests/Makefile
|
|
oe_runmake check
|
|
}
|
|
|
|
do_install_ptest() {
|
|
install -d ${D}${PTEST_PATH}/tests
|
|
install -m 0755 ${S}/test-driver ${D}${PTEST_PATH}/
|
|
cp -rf ${B}/tests/.libs/* ${D}${PTEST_PATH}/tests/
|
|
cp -rf ${B}/tests/test_simple ${D}${PTEST_PATH}/tests/
|
|
cp -rf ${S}/tests/mansyntax.sh ${D}${PTEST_PATH}/tests/
|
|
cp -rf ${S}/tests/key* ${D}${PTEST_PATH}/tests/
|
|
cp -rf ${S}/tests/openssh_server/ ${D}${PTEST_PATH}/tests/
|
|
cp -rf ${S}/tests/*.test ${D}${PTEST_PATH}/tests/
|
|
mkdir -p ${D}${PTEST_PATH}/docs
|
|
cp -r ${S}/docs/* ${D}${PTEST_PATH}/docs/
|
|
}
|