mirror of
https://git.yoctoproject.org/poky
synced 2026-04-24 12:32:11 +02:00
016e3dda2d
Add a backported patch to fix big endian compilation. (From OE-Core rev: 9f5f4b31df01a29fd07ce27efc7534b4ea29a778) Signed-off-by: Alexander Kanavin <alex.kanavin@gmail.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
46 lines
1.7 KiB
BlitzBasic
46 lines
1.7 KiB
BlitzBasic
SUMMARY = "Checksumming Copy on Write Filesystem utilities"
|
|
DESCRIPTION = "Btrfs is a new copy on write filesystem for Linux aimed at \
|
|
implementing advanced features while focusing on fault tolerance, repair and \
|
|
easy administration. \
|
|
This package contains utilities (mkfs, fsck, btrfsctl) used to work with \
|
|
btrfs and an utility (btrfs-convert) to make a btrfs filesystem from an ext3."
|
|
|
|
HOMEPAGE = "https://btrfs.wiki.kernel.org"
|
|
|
|
LICENSE = "GPLv2"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=fcb02dc552a041dee27e4b85c7396067"
|
|
SECTION = "base"
|
|
DEPENDS = "util-linux attr e2fsprogs lzo acl python3-setuptools-native"
|
|
DEPENDS_append_class-target = " udev"
|
|
RDEPENDS_${PN} = "libgcc"
|
|
|
|
SRCREV = "d72d913291683188ddf5d758db02f1bc3b05d2f7"
|
|
SRC_URI = "git://git.kernel.org/pub/scm/linux/kernel/git/kdave/btrfs-progs.git \
|
|
file://0001-Makefile-build-mktables-using-native-gcc.patch \
|
|
file://0001-Add-LDFLAGS-when-building-libbtrfsutil.so.patch \
|
|
file://0001-Add-a-possibility-to-specify-where-python-modules-ar.patch \
|
|
file://0001-btrfs-progs-kernel-lib-bitops-Fix-big-endian-compila.patch \
|
|
"
|
|
|
|
inherit autotools-brokensep pkgconfig manpages distutils3-base
|
|
|
|
CLEANBROKEN = "1"
|
|
|
|
PACKAGECONFIG[manpages] = "--enable-documentation, --disable-documentation, asciidoc-native xmlto-native"
|
|
EXTRA_OECONF = " --disable-zstd"
|
|
EXTRA_OECONF_append_libc-musl = " --disable-backtrace "
|
|
|
|
do_configure_prepend() {
|
|
# Upstream doesn't ship this and autoreconf won't install it as automake isn't used.
|
|
mkdir -p ${S}/config
|
|
cp -f $(automake --print-libdir)/install-sh ${S}/config/
|
|
}
|
|
|
|
S = "${WORKDIR}/git"
|
|
|
|
do_install_append() {
|
|
oe_runmake 'DESTDIR=${D}' 'PYTHON_SITEPACKAGES_DIR=${PYTHON_SITEPACKAGES_DIR}' install_python
|
|
}
|
|
|
|
BBCLASSEXTEND = "native"
|