mirror of
https://git.yoctoproject.org/poky
synced 2026-03-31 02:02:25 +02:00
24380e2be9
Rebased support-oe-qt4-tools-names as some of the changes where added in the upstream code. (From OE-Core rev: 13399264e987b698b120688dc5018adb3fa8522d) Signed-off-by: Saul Wold <sgw@linux.intel.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
39 lines
1.2 KiB
BlitzBasic
39 lines
1.2 KiB
BlitzBasic
require cmake.inc
|
|
|
|
inherit cmake
|
|
|
|
DEPENDS += "curl expat zlib libarchive ncurses"
|
|
|
|
SRC_URI += "file://dont-run-cross-binaries.patch"
|
|
|
|
SRC_URI[md5sum] = "be6008f2299613d23fe82ab53ef7472e"
|
|
SRC_URI[sha256sum] = "20d0d3661797fa82c19e7a75c7315c640e001cb3238331ca170bb0fae27feee5"
|
|
|
|
# Strip ${prefix} from ${docdir}, set result into docdir_stripped
|
|
python () {
|
|
prefix=d.getVar("prefix", True)
|
|
docdir=d.getVar("docdir", True)
|
|
|
|
if not docdir.startswith(prefix):
|
|
raise bb.build.FuncFailed('docdir must contain prefix as its prefix')
|
|
|
|
docdir_stripped = docdir[len(prefix):]
|
|
if len(docdir_stripped) > 0 and docdir_stripped[0] == '/':
|
|
docdir_stripped = docdir_stripped[1:]
|
|
|
|
d.setVar("docdir_stripped", docdir_stripped)
|
|
}
|
|
|
|
EXTRA_OECMAKE=" \
|
|
-DCMAKE_DOC_DIR=${docdir_stripped}/cmake-${CMAKE_MAJOR_VERSION} \
|
|
-DCMAKE_USE_SYSTEM_LIBRARIES=1 \
|
|
-DKWSYS_CHAR_IS_SIGNED=1 \
|
|
-DBUILD_CursesDialog=0 \
|
|
${@base_contains('DISTRO_FEATURES', 'largefile', '-DKWSYS_LFS_WORKS=1', '-DKWSYS_LFS_DISABLE=1', d)} \
|
|
"
|
|
|
|
FILES_${PN} += "${datadir}/cmake-${CMAKE_MAJOR_VERSION}"
|
|
FILES_${PN}-doc += "${docdir}/cmake-${CMAKE_MAJOR_VERSION}"
|
|
|
|
BBCLASSEXTEND = "nativesdk"
|