mirror of
https://git.yoctoproject.org/poky
synced 2026-04-25 15:32:13 +02:00
c9a512b640
(From OE-Core rev: 1e15dea62cacdd5c3c1158962a55ca44cfb1726b) (From OE-Core rev: 76e5ecbe75c6ef06af7dd662625631399cbbde0f) Signed-off-by: Alexander Kanavin <alexander.kanavin@linux.intel.com> Signed-off-by: Ross Burton <ross.burton@intel.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
50 lines
1.5 KiB
BlitzBasic
50 lines
1.5 KiB
BlitzBasic
require cmake.inc
|
|
|
|
inherit cmake
|
|
|
|
DEPENDS += "curl expat zlib libarchive xz ncurses bzip2"
|
|
|
|
SRC_URI_append_class-nativesdk = " \
|
|
file://OEToolchainConfig.cmake \
|
|
file://environment.d-cmake.sh"
|
|
|
|
# Strip ${prefix} from ${docdir}, set result into docdir_stripped
|
|
python () {
|
|
prefix=d.getVar("prefix")
|
|
docdir=d.getVar("docdir")
|
|
|
|
if not docdir.startswith(prefix):
|
|
bb.fatal('docdir must contain prefix as its prefix')
|
|
|
|
docdir_stripped = docdir[len(prefix):]
|
|
if len(docdir_stripped) > 0 and docdir_stripped[0] == '/':
|
|
docdir_stripped = docdir_stripped[1:]
|
|
|
|
d.setVar("docdir_stripped", docdir_stripped)
|
|
}
|
|
|
|
EXTRA_OECMAKE=" \
|
|
-DCMAKE_DOC_DIR=${docdir_stripped}/cmake-${CMAKE_MAJOR_VERSION} \
|
|
-DCMAKE_USE_SYSTEM_LIBRARIES=1 \
|
|
-DCMAKE_USE_SYSTEM_LIBRARY_JSONCPP=0 \
|
|
-DCMAKE_USE_SYSTEM_LIBRARY_LIBUV=0 \
|
|
-DKWSYS_CHAR_IS_SIGNED=1 \
|
|
-DBUILD_CursesDialog=0 \
|
|
${@bb.utils.contains('DISTRO_FEATURES', 'largefile', '-DKWSYS_LFS_WORKS=1', '-DKWSYS_LFS_DISABLE=1', d)} \
|
|
"
|
|
|
|
do_install_append_class-nativesdk() {
|
|
mkdir -p ${D}${datadir}/cmake
|
|
install -m 644 ${WORKDIR}/OEToolchainConfig.cmake ${D}${datadir}/cmake/
|
|
|
|
mkdir -p ${D}${SDKPATHNATIVE}/environment-setup.d
|
|
install -m 644 ${WORKDIR}/environment.d-cmake.sh ${D}${SDKPATHNATIVE}/environment-setup.d/cmake.sh
|
|
}
|
|
|
|
FILES_${PN}_append_class-nativesdk = " ${SDKPATHNATIVE}"
|
|
|
|
FILES_${PN} += "${datadir}/cmake-${CMAKE_MAJOR_VERSION}"
|
|
FILES_${PN}-doc += "${docdir}/cmake-${CMAKE_MAJOR_VERSION}"
|
|
|
|
BBCLASSEXTEND = "nativesdk"
|