mirror of
https://git.yoctoproject.org/poky
synced 2026-02-08 18:02:12 +01:00
97b5653585
The hostname removal from the script is useful to make libtool-cross reproduce. Apply the patch everywhere as it doesn't cause any issues. (From OE-Core rev: f1cc4b8d7503331f04d3f217ae67d0fd4cc483c5) Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org> (cherry picked from commit 3c61c6f20187154d677085fc9ccdcd762d4cdf3a) Signed-off-by: Steve Sakoman <steve@sakoman.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
35 lines
1.0 KiB
BlitzBasic
35 lines
1.0 KiB
BlitzBasic
require libtool-${PV}.inc
|
|
|
|
SRC_URI += "file://multilib.patch"
|
|
|
|
RDEPENDS_${PN} += "bash"
|
|
|
|
#
|
|
# We want the results of libtool-cross preserved - don't stage anything ourselves.
|
|
#
|
|
SYSROOT_DIRS_BLACKLIST += " \
|
|
${bindir} \
|
|
${datadir}/aclocal \
|
|
${datadir}/libtool/build-aux \
|
|
"
|
|
|
|
ACLOCALEXTRAPATH_class-target = ""
|
|
|
|
do_install_append () {
|
|
sed -e 's@--sysroot=${STAGING_DIR_HOST}@@g' \
|
|
-e "s@${DEBUG_PREFIX_MAP}@@g" \
|
|
-e 's@${STAGING_DIR_HOST}@@g' \
|
|
-e 's@${STAGING_DIR_NATIVE}@@g' \
|
|
-e 's@^\(sys_lib_search_path_spec="\).*@\1${libdir} ${base_libdir}"@' \
|
|
-e 's@^\(compiler_lib_search_dirs="\).*@\1${libdir} ${base_libdir}"@' \
|
|
-e 's@^\(compiler_lib_search_path="\).*@\1${libdir} ${base_libdir}"@' \
|
|
-e 's@^\(predep_objects="\).*@\1"@' \
|
|
-e 's@^\(postdep_objects="\).*@\1"@' \
|
|
-e "s@${HOSTTOOLS_DIR}/@@g" \
|
|
-i ${D}${bindir}/libtool
|
|
}
|
|
|
|
inherit multilib_script
|
|
|
|
MULTILIB_SCRIPTS = "${PN}:${bindir}/libtool"
|