mirror of
https://git.yoctoproject.org/poky
synced 2026-03-29 14:02:22 +02:00
2c9d9bc342
refresh 0001-CMakeDetermineSystem-use-oe-environment-vars-to-load.patch Changelog: ========== * The :command:'while' command again ignores errors in condition evaluation as CMake 3.21 and below did. This bug was fixed in 3.22.0, but exposed errors in existing projects. The fix has been reverted to restore compatibility. The fix may be restored in a future version of CMake via a policy. (From OE-Core rev: 146ceceaf81639085a82fd94d30ea84150a75e3a) Signed-off-by: Wang Mingyu <wangmy@fujitsu.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
57 lines
1.8 KiB
BlitzBasic
57 lines
1.8 KiB
BlitzBasic
require cmake.inc
|
|
inherit native
|
|
|
|
DEPENDS += "bzip2-replacement-native xz-native zlib-native curl-native ncurses-native zstd-native"
|
|
|
|
SRC_URI += "file://OEToolchainConfig.cmake \
|
|
file://environment.d-cmake.sh \
|
|
file://0001-CMakeDetermineSystem-use-oe-environment-vars-to-load.patch \
|
|
file://0005-Disable-use-of-ext2fs-ext2_fs.h-by-cmake-s-internal-.patch \
|
|
"
|
|
|
|
|
|
B = "${WORKDIR}/build"
|
|
do_configure[cleandirs] = "${B}"
|
|
|
|
CMAKE_EXTRACONF = "\
|
|
-DCMAKE_LIBRARY_PATH=${STAGING_LIBDIR_NATIVE} \
|
|
-DBUILD_CursesDialog=1 \
|
|
-DCMAKE_USE_SYSTEM_LIBRARIES=1 \
|
|
-DCMAKE_USE_SYSTEM_LIBRARY_JSONCPP=0 \
|
|
-DCMAKE_USE_SYSTEM_LIBRARY_LIBARCHIVE=0 \
|
|
-DCMAKE_USE_SYSTEM_LIBRARY_LIBUV=0 \
|
|
-DCMAKE_USE_SYSTEM_LIBRARY_LIBRHASH=0 \
|
|
-DCMAKE_USE_SYSTEM_LIBRARY_EXPAT=0 \
|
|
-DENABLE_ACL=0 -DHAVE_ACL_LIBACL_H=0 \
|
|
-DHAVE_SYS_ACL_H=0 \
|
|
"
|
|
|
|
do_configure () {
|
|
${S}/configure --verbose --prefix=${prefix} \
|
|
${@oe.utils.parallel_make_argument(d, '--parallel=%d')} \
|
|
${@bb.utils.contains('CCACHE', 'ccache ', '--enable-ccache', '', d)} \
|
|
-- ${CMAKE_EXTRACONF}
|
|
}
|
|
|
|
do_compile() {
|
|
oe_runmake
|
|
}
|
|
|
|
do_install() {
|
|
oe_runmake 'DESTDIR=${D}' install
|
|
|
|
# The following codes are here because eSDK needs to provide compatibilty
|
|
# for SDK. That is, eSDK could also be used like traditional SDK.
|
|
mkdir -p ${D}${datadir}/cmake
|
|
install -m 644 ${WORKDIR}/OEToolchainConfig.cmake ${D}${datadir}/cmake/
|
|
mkdir -p ${D}${base_prefix}/environment-setup.d
|
|
install -m 644 ${WORKDIR}/environment.d-cmake.sh ${D}${base_prefix}/environment-setup.d/cmake.sh
|
|
|
|
# Help docs create tons of files in the native sysroot and aren't needed there
|
|
rm -rf ${D}${datadir}/cmake-*/Help
|
|
}
|
|
|
|
do_compile[progress] = "percent"
|
|
|
|
SYSROOT_DIRS_NATIVE += "${datadir}/cmake ${base_prefix}/environment-setup.d"
|