mirror of
https://git.yoctoproject.org/poky
synced 2026-04-29 18:32:20 +02:00
370fd9b3fb
Add config option for pulseaudio Change audio to default mode since quoting of list of devices is broken in meson Drop patch where code changed completed upstream Refresh other patches (From OE-Core rev: c1685b06e5f3684b1b5631b99b412e3ec2b10800) Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
33 lines
1.1 KiB
BlitzBasic
33 lines
1.1 KiB
BlitzBasic
BPN = "qemu"
|
|
|
|
inherit python3-dir
|
|
|
|
require qemu-native.inc
|
|
|
|
# As some of the files installed by qemu-native and qemu-system-native
|
|
# are the same, we depend on qemu-native to get the full installation set
|
|
# and avoid file clashes
|
|
DEPENDS = "glib-2.0-native zlib-native pixman-native qemu-native bison-native meson-native ninja-native"
|
|
|
|
EXTRA_OECONF:append = " --target-list=${@get_qemu_system_target_list(d)}"
|
|
|
|
PACKAGECONFIG ??= "fdt alsa kvm pie \
|
|
${@bb.utils.contains('DISTRO_FEATURES', 'opengl', 'virglrenderer glx', '', d)} \
|
|
"
|
|
|
|
# Handle distros such as CentOS 5 32-bit that do not have kvm support
|
|
PACKAGECONFIG:remove = "${@'kvm' if not os.path.exists('/usr/include/linux/kvm.h') else ''}"
|
|
|
|
do_install:append() {
|
|
install -Dm 0755 ${WORKDIR}/powerpc_rom.bin ${D}${datadir}/qemu
|
|
|
|
# The following is also installed by qemu-native
|
|
rm -f ${D}${datadir}/qemu/trace-events-all
|
|
rm -rf ${D}${datadir}/qemu/keymaps
|
|
rm -rf ${D}${datadir}/icons/
|
|
rm -rf ${D}${includedir}/qemu-plugin.h
|
|
|
|
# Install qmp.py to be used with testimage
|
|
install -D ${S}/python/qemu/qmp/__init__.py ${D}${libdir}/qemu-python/qmp.py
|
|
}
|