mirror of
https://git.yoctoproject.org/poky
synced 2026-02-12 19:53:03 +01:00
a1b9c06ff5
The per-tune qemu options variable is QEMU_EXTRAOPTIONS_${TUNE_PKGARCH},
but this doesn't follow the pattern of all of the other tune-specific
variables in the machine configuration which is VARIABLE:tune-[name].
Rename QEMU_EXTRAOPTIONS_${TUNE_PKGARCH} to
QEMU_EXTRAOPTIONS:tune-${TUNE_PKGARCH} for consistency.
Note that this will mean that BSPs need to update any assignments of
this variable.
(From OE-Core rev: 7f981d074442b901f7e64dbdb9db851ff31c3733)
Signed-off-by: Ross Burton <ross.burton@arm.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
65 lines
2.4 KiB
Plaintext
65 lines
2.4 KiB
Plaintext
#
|
|
# Copyright OpenEmbedded Contributors
|
|
#
|
|
# SPDX-License-Identifier: MIT
|
|
#
|
|
|
|
#
|
|
# This class contains functions for recipes that need QEMU or test for its
|
|
# existence.
|
|
#
|
|
|
|
def qemu_target_binary(data):
|
|
package_arch = data.getVar("PACKAGE_ARCH")
|
|
qemu_target_binary = (data.getVar("QEMU_TARGET_BINARY_%s" % package_arch) or "")
|
|
if qemu_target_binary:
|
|
return qemu_target_binary
|
|
|
|
target_arch = data.getVar("TARGET_ARCH")
|
|
if target_arch in ("i486", "i586", "i686"):
|
|
target_arch = "i386"
|
|
elif target_arch == "powerpc":
|
|
target_arch = "ppc"
|
|
elif target_arch == "powerpc64":
|
|
target_arch = "ppc64"
|
|
elif target_arch == "powerpc64le":
|
|
target_arch = "ppc64le"
|
|
|
|
return "qemu-" + target_arch
|
|
|
|
def qemu_wrapper_cmdline(data, rootfs_path, library_paths):
|
|
import string
|
|
|
|
qemu_binary = qemu_target_binary(data)
|
|
if qemu_binary == "qemu-allarch":
|
|
qemu_binary = "qemuwrapper"
|
|
|
|
qemu_options = data.getVar("QEMU_OPTIONS") or ""
|
|
|
|
return "PSEUDO_UNLOAD=1 " + qemu_binary + " " + qemu_options + " -L " + rootfs_path\
|
|
+ " -E LD_LIBRARY_PATH=" + ":".join(library_paths) + " "
|
|
|
|
# Next function will return a string containing the command that is needed to
|
|
# to run a certain binary through qemu. For example, in order to make a certain
|
|
# postinstall scriptlet run at do_rootfs time and running the postinstall is
|
|
# architecture dependent, we can run it through qemu. For example, in the
|
|
# postinstall scriptlet, we could use the following:
|
|
#
|
|
# ${@qemu_run_binary(d, '$D', '/usr/bin/test_app')} [test_app arguments]
|
|
#
|
|
def qemu_run_binary(data, rootfs_path, binary):
|
|
libdir = rootfs_path + data.getVar("libdir", False)
|
|
base_libdir = rootfs_path + data.getVar("base_libdir", False)
|
|
|
|
return qemu_wrapper_cmdline(data, rootfs_path, [libdir, base_libdir]) + rootfs_path + binary
|
|
|
|
# QEMU_EXTRAOPTIONS is not meant to be directly used, the extensions are
|
|
# PACKAGE_ARCH, *NOT* overrides.
|
|
# In some cases (e.g. ppc) simply being arch specific (apparently) isn't good
|
|
# enough and a PACKAGE_ARCH specific -cpu option is needed (hence we have to do
|
|
# this dance). For others (e.g. arm) a -cpu option is not necessary, since the
|
|
# qemu-arm default CPU supports all required architecture levels.
|
|
|
|
QEMU_OPTIONS = "-r ${OLDEST_KERNEL} ${@d.getVar("QEMU_EXTRAOPTIONS:tune-%s" % d.getVar('TUNE_PKGARCH')) or ""}"
|
|
QEMU_OPTIONS[vardeps] += "QEMU_EXTRAOPTIONS:tune-${TUNE_PKGARCH}"
|