mirror of
https://git.yoctoproject.org/poky
synced 2026-02-05 00:08:47 +01:00
c0bc969ce0
(From OE-Core rev: 4cd22618a41c87bf877949c1c38da61eb0e2a1f3) Signed-off-by: Wang Mingyu <wangmy@fujitsu.com> Signed-off-by: Mathieu Dubois-Briand <mathieu.dubois-briand@bootlin.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
41 lines
1.4 KiB
BlitzBasic
41 lines
1.4 KiB
BlitzBasic
SUMMARY = "Python GObject bindings"
|
|
HOMEPAGE = "https://gitlab.gnome.org/GNOME/pygobject"
|
|
DESCRIPTION = "PyGObject is a Python package which provides bindings for GObject based libraries such as GTK, GStreamer, WebKitGTK, GLib, GIO and many more."
|
|
SECTION = "devel/python"
|
|
LICENSE = "LGPL-2.1-only"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=a916467b91076e631dd8edb7424769c7"
|
|
|
|
GIR_MESON_OPTION = ""
|
|
|
|
inherit gnomebase setuptools3-base gobject-introspection upstream-version-is-even
|
|
|
|
python() {
|
|
if d.getVar('CLASSOVERRIDE') == "class-target" and not bb.utils.to_boolean(d.getVar("GI_DATA_ENABLED")):
|
|
raise bb.parse.SkipRecipe("GI not available")
|
|
}
|
|
|
|
DEPENDS += "python3 glib-2.0"
|
|
|
|
SRCNAME = "pygobject"
|
|
|
|
SRC_URI = "http://ftp.gnome.org/pub/GNOME/sources/${SRCNAME}/${@gnome_verdir("${PV}")}/${SRCNAME}-${PV}.tar.gz"
|
|
SRC_URI[sha256sum] = "869f42ee70dcf6de50bce267072e2c35cee7fcd2e32ea1af3a3a99a88901850a"
|
|
|
|
S = "${WORKDIR}/${SRCNAME}-${PV}"
|
|
|
|
PACKAGECONFIG ??= "${@bb.utils.contains_any('DISTRO_FEATURES', [ 'directfb', 'wayland', 'x11' ], 'cairo', '', d)}"
|
|
|
|
RDEPENDS:${PN} += " \
|
|
python3-asyncio \
|
|
python3-io \
|
|
python3-pkgutil \
|
|
"
|
|
|
|
# python3-pycairo is checked on configuration -> DEPENDS
|
|
# we don't link against python3-pycairo -> RDEPENDS
|
|
PACKAGECONFIG[cairo] = "-Dpycairo=enabled,-Dpycairo=disabled, cairo python3-pycairo, python3-pycairo"
|
|
PACKAGECONFIG[tests] = "-Dtests=true,-Dtests=false,"
|
|
|
|
BBCLASSEXTEND = "native"
|
|
PACKAGECONFIG:class-native = ""
|