mirror of
https://git.yoctoproject.org/poky
synced 2026-04-26 18:32:13 +02:00
efb0410d38
There is no need to have two assignments; also setting S from UNPACKDIR (and not vice versa) is more logical as unpack task comes first, and tasks that come after unpack use S to access unpack results. Also adjust reference test data in selftest/recipeutils to reflect changes in test recipes. (From OE-Core rev: f64b7e5fb3181734c8dde87b27e872a026261a74) Signed-off-by: Alexander Kanavin <alex@linutronix.de> Signed-off-by: Mathieu Dubois-Briand <mathieu.dubois-briand@bootlin.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
47 lines
1.2 KiB
BlitzBasic
47 lines
1.2 KiB
BlitzBasic
SUMMARY = "Runs postinstall scripts on first boot of the target device"
|
|
DESCRIPTION = "${SUMMARY}"
|
|
SECTION = "devel"
|
|
LICENSE = "MIT"
|
|
LIC_FILES_CHKSUM = "file://${COREBASE}/meta/COPYING.MIT;md5=3da9cfbcb788c80a0384361b4de20420"
|
|
|
|
SRC_URI = "file://run-postinsts \
|
|
file://run-postinsts.init \
|
|
file://run-postinsts.service"
|
|
|
|
S = "${UNPACKDIR}"
|
|
|
|
inherit allarch systemd update-rc.d
|
|
|
|
RDEPENDS:${PN} = "util-linux-fcntl-lock"
|
|
|
|
INITSCRIPT_NAME = "run-postinsts"
|
|
INITSCRIPT_PARAMS = "start 99 S ."
|
|
|
|
SYSTEMD_SERVICE:${PN} = "run-postinsts.service"
|
|
|
|
do_configure() {
|
|
:
|
|
}
|
|
|
|
do_compile () {
|
|
:
|
|
}
|
|
|
|
do_install() {
|
|
install -d ${D}${sbindir}
|
|
install -m 0755 ${S}/run-postinsts ${D}${sbindir}/
|
|
|
|
install -d ${D}${sysconfdir}/init.d/
|
|
install -m 0755 ${S}/run-postinsts.init ${D}${sysconfdir}/init.d/run-postinsts
|
|
|
|
install -d ${D}${systemd_system_unitdir}/
|
|
install -m 0644 ${S}/run-postinsts.service ${D}${systemd_system_unitdir}/
|
|
|
|
sed -i -e 's:#SYSCONFDIR#:${sysconfdir}:g' \
|
|
-e 's:#SBINDIR#:${sbindir}:g' \
|
|
-e 's:#BASE_BINDIR#:${base_bindir}:g' \
|
|
-e 's:#LOCALSTATEDIR#:${localstatedir}:g' \
|
|
${D}${sbindir}/run-postinsts \
|
|
${D}${systemd_system_unitdir}/run-postinsts.service
|
|
}
|