mirror of
https://git.yoctoproject.org/poky
synced 2026-03-29 05:02:22 +02:00
65da09ad88
Drop 0001-Add-P-prompt-into-Usage-info.patch since it is already fixed upstream. (From OE-Core rev: 02f8aff020762e77bf49587115f6b8fbc96296c9) Signed-off-by: Yi Zhao <yi.zhao@windriver.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
48 lines
1.4 KiB
BlitzBasic
48 lines
1.4 KiB
BlitzBasic
SUMMARY = "File classification tool"
|
|
DESCRIPTION = "File attempts to classify files depending \
|
|
on their contents and prints a description if a match is found."
|
|
HOMEPAGE = "http://www.darwinsys.com/file/"
|
|
SECTION = "console/utils"
|
|
|
|
# two clause BSD
|
|
LICENSE = "BSD"
|
|
LIC_FILES_CHKSUM = "file://COPYING;beginline=2;md5=6a7382872edb68d33e1a9398b6e03188"
|
|
|
|
DEPENDS = "zlib file-replacement-native"
|
|
DEPENDS_class-native = "zlib-native"
|
|
|
|
# Blacklist a bogus tag in upstream check
|
|
UPSTREAM_CHECK_GITTAGREGEX = "FILE(?P<pver>(?!6_23).+)"
|
|
|
|
SRC_URI = "git://github.com/file/file.git \
|
|
file://debian-742262.patch \
|
|
"
|
|
|
|
SRCREV = "219846094c7593e27453e62855e61181089c48cf"
|
|
S = "${WORKDIR}/git"
|
|
|
|
inherit autotools
|
|
|
|
EXTRA_OEMAKE_append_class-target = "-e FILE_COMPILE=${STAGING_BINDIR_NATIVE}/file-native/file"
|
|
EXTRA_OEMAKE_append_class-nativesdk = "-e FILE_COMPILE=${STAGING_BINDIR_NATIVE}/file-native/file"
|
|
|
|
CFLAGS_append = " -std=c99"
|
|
|
|
FILES_${PN} += "${datadir}/misc/*.mgc"
|
|
|
|
do_install_append_class-native() {
|
|
create_cmdline_wrapper ${D}/${bindir}/file \
|
|
--magic-file ${datadir}/misc/magic.mgc
|
|
}
|
|
|
|
do_install_append_class-nativesdk() {
|
|
create_cmdline_wrapper ${D}/${bindir}/file \
|
|
--magic-file ${datadir}/misc/magic.mgc
|
|
}
|
|
|
|
BBCLASSEXTEND = "native nativesdk"
|
|
PROVIDES_append_class-native = " file-replacement-native"
|
|
# Don't use NATIVE_PACKAGE_PATH_SUFFIX as that hides libmagic from anyone who
|
|
# depends on file-replacement-native.
|
|
bindir_append_class-native = "/file-native"
|