mirror of
https://git.yoctoproject.org/poky
synced 2026-09-29 07:36:20 +02:00
cef8bc9e80
The new class uses gio-querymodules tool on postinst and postrm. This regenerates the module cache which is useful to avoid loading modules that are not needed at runtime: If a Gio module is not listed in the cache file it will always get loaded. * Add a postinst-intercept 'gio-module-cache': it runs gio-querymodules using qemuwrapper. This is required because the tool actually loads the modules to generate the cache. * Add a gio-module-cache class that adds postinstall and postrm scripts. In the sysroot population case use the new intercept. * Inherit the new class in glib-2.0, glib-networking and gconf. Fixes [YOCTO #9241]. (From OE-Core rev: 168cf5502a2dda78348cc9679e37bed0c69c0208) Signed-off-by: Jussi Kukkonen <jussi.kukkonen@intel.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
55 lines
1.8 KiB
BlitzBasic
55 lines
1.8 KiB
BlitzBasic
SUMMARY = "GNOME configuration system"
|
|
SECTION = "x11/gnome"
|
|
LICENSE = "LGPLv2+"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=55ca817ccb7d5b5b66355690e9abc605"
|
|
|
|
DEPENDS = "glib-2.0 dbus dbus-glib libxml2 intltool-native"
|
|
|
|
inherit gnomebase gtk-doc gettext gobject-introspection gio-module-cache
|
|
|
|
SRC_URI = "${GNOME_MIRROR}/GConf/${@gnome_verdir("${PV}")}/GConf-${PV}.tar.xz;name=archive \
|
|
file://remove_plus_from_invalid_characters_list.patch \
|
|
file://unable-connect-dbus.patch \
|
|
"
|
|
|
|
SRC_URI[archive.md5sum] = "2b16996d0e4b112856ee5c59130e822c"
|
|
SRC_URI[archive.sha256sum] = "1912b91803ab09a5eed34d364bf09fe3a2a9c96751fde03a4e0cfa51a04d784c"
|
|
|
|
S = "${WORKDIR}/GConf-${PV}"
|
|
|
|
EXTRA_OECONF = "--enable-shared --disable-static \
|
|
--disable-orbit --with-openldap=no --disable-gtk"
|
|
|
|
# Disable PolicyKit by default
|
|
PACKAGECONFIG ??= ""
|
|
# We really don't want PolicyKit for native or uclibc
|
|
PACKAGECONFIG_class-native = ""
|
|
PACKAGECONFIG_libc-uclibc = ""
|
|
|
|
PACKAGECONFIG[policykit] = "--enable-defaults-service,--disable-defaults-service,polkit"
|
|
PACKAGECONFIG[debug] = "--enable-debug=yes, --enable-debug=minimum"
|
|
|
|
do_install_append() {
|
|
# this directory need to be created to avoid an Error 256 at gdm launch
|
|
install -d ${D}${sysconfdir}/gconf/gconf.xml.system
|
|
|
|
# this stuff is unusable
|
|
rm -f ${D}${libdir}/GConf/*/*.*a
|
|
rm -f ${D}${libdir}/gio/*/*.*a
|
|
}
|
|
|
|
do_install_append_class-native() {
|
|
create_wrapper ${D}/${bindir}/gconftool-2 \
|
|
GCONF_BACKEND_DIR=${STAGING_LIBDIR_NATIVE}/GConf/2
|
|
}
|
|
|
|
FILES_${PN} += "${libdir}/GConf/* \
|
|
${libdir}/gio/*/*.so \
|
|
${datadir}/polkit* \
|
|
${datadir}/dbus-1/services/*.service \
|
|
${datadir}/dbus-1/system-services/*.service \
|
|
"
|
|
FILES_${PN}-dev += "${datadir}/sgml/gconf/gconf-1.0.dtd"
|
|
|
|
BBCLASSEXTEND = "native"
|