mirror of
https://git.yoctoproject.org/poky
synced 2026-04-26 00:32:12 +02:00
1a99396ed5
(From OE-Core rev: e7cbfd0573b77d7debab3fbf4b05565ac8b33f3a) Signed-off-by: Ross Burton <ross.burton@arm.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
53 lines
2.2 KiB
BlitzBasic
53 lines
2.2 KiB
BlitzBasic
SUMMARY = "Text shaping library"
|
|
DESCRIPTION = "HarfBuzz is an OpenType text shaping engine."
|
|
HOMEPAGE = "http://www.freedesktop.org/wiki/Software/HarfBuzz"
|
|
BUGTRACKER = "https://bugs.freedesktop.org/enter_bug.cgi?product=HarfBuzz"
|
|
SECTION = "libs"
|
|
LICENSE = "MIT"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=8f787620b7d3866d9552fd1924c07572 \
|
|
file://src/hb-ucd.cc;beginline=1;endline=15;md5=29d4dcb6410429195df67efe3382d8bc"
|
|
|
|
UPSTREAM_CHECK_URI = "https://github.com/${BPN}/${BPN}/releases"
|
|
UPSTREAM_CHECK_REGEX = "harfbuzz-(?P<pver>\d+(\.\d+)+).tar"
|
|
|
|
SRC_URI = "https://github.com/${BPN}/${BPN}/releases/download/${PV}/${BPN}-${PV}.tar.xz \
|
|
file://0001-Do-not-disable-introspection-in-cross-builds.patch \
|
|
file://0001-src-hb-gobject-enums.cc.tmpl-write-out-only-the-file.patch \
|
|
file://version-race.patch \
|
|
"
|
|
SRC_URI[sha256sum] = "b8c048d7c2964a12f2c80deb6634dfc836b603dd12bf0d0a3df1627698e220ce"
|
|
|
|
inherit meson pkgconfig lib_package gtk-doc gobject-introspection
|
|
|
|
GIR_MESON_ENABLE_FLAG = 'enabled'
|
|
GIR_MESON_DISABLE_FLAG = 'disabled'
|
|
GTKDOC_MESON_ENABLE_FLAG = 'enabled'
|
|
GTKDOC_MESON_DISABLE_FLAG = 'disabled'
|
|
|
|
PACKAGECONFIG ??= "cairo fontconfig freetype glib icu"
|
|
PACKAGECONFIG[cairo] = "-Dcairo=enabled,-Dcairo=disabled,cairo"
|
|
PACKAGECONFIG[fontconfig] = "-Dfontconfig=enabled,-Dfontconfig=disabled,fontconfig"
|
|
PACKAGECONFIG[freetype] = "-Dfreetype=enabled,-Dfreetype=disabled,freetype"
|
|
PACKAGECONFIG[glib] = "-Dglib=enabled,-Dglib=disabled,glib-2.0"
|
|
PACKAGECONFIG[graphite] = "-Dgraphite=enabled,-Dgraphite=disabled,graphite2"
|
|
PACKAGECONFIG[icu] = "-Dicu=enabled,-Dicu=disabled,icu"
|
|
|
|
PACKAGES =+ "${PN}-icu ${PN}-icu-dev ${PN}-subset"
|
|
|
|
LEAD_SONAME = "libharfbuzz.so"
|
|
|
|
do_install_append() {
|
|
# If no tools are installed due to PACKAGECONFIG then this directory is
|
|
#still installed, so remove it to stop packaging wanings.
|
|
rmdir --ignore-fail-on-non-empty ${D}${bindir}
|
|
}
|
|
|
|
FILES_${PN}-icu = "${libdir}/libharfbuzz-icu.so.*"
|
|
FILES_${PN}-icu-dev = "${libdir}/libharfbuzz-icu.la \
|
|
${libdir}/libharfbuzz-icu.so \
|
|
${libdir}/pkgconfig/harfbuzz-icu.pc \
|
|
"
|
|
FILES_${PN}-subset = "${libdir}/libharfbuzz-subset.so.*"
|
|
|
|
BBCLASSEXTEND = "native nativesdk"
|