mirror of
https://git.yoctoproject.org/poky
synced 2026-02-09 18:23:02 +01:00
cc55fc78fb
fts is not implemented in musl but many packages depend on it glibc implements it even though posix does not requir it to do so. So provide an alternative provider for fts (From OE-Core rev: 387f84899cc93c06f3e29991c2fc6c1157bddd81) Signed-off-by: Khem Raj <raj.khem@gmail.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
40 lines
1.2 KiB
BlitzBasic
40 lines
1.2 KiB
BlitzBasic
# Copyright (C) 2015 Khem Raj <raj.khem@gmail.com>
|
|
# Released under the MIT license (see COPYING.MIT for the terms)
|
|
|
|
DESCRIPTION = "keith bostic's POSIX file tree stream operations library"
|
|
HOMEPAGE = "https://sites.google.com/a/bostic.com/keithbostic"
|
|
LICENSE = "BSD-4-Clause"
|
|
LIC_FILES_CHECKSUM = "file://${COREBASE}/meta/files/common-licenses/BSD-4-Clause;md5=624d9e67e8ac41a78f6b6c2c55a83a2b"
|
|
SECTION = "libs"
|
|
|
|
SRC_URI = "https://sites.google.com/a/bostic.com/keithbostic/files/fts.tar.gz \
|
|
file://fts-header-correctness.patch \
|
|
file://fts-uclibc.patch \
|
|
file://remove_cdefs.patch \
|
|
file://stdint.patch \
|
|
file://gcc5.patch \
|
|
"
|
|
|
|
SRC_URI[md5sum] = "120c14715485ec6ced14f494d059d20a"
|
|
SRC_URI[sha256sum] = "3df9b9b5a45aeaf16f33bb84e692a10dc662e22ec8a51748f98767d67fb6f342"
|
|
|
|
S = "${WORKDIR}/${BPN}"
|
|
|
|
do_configure[noexec] = "1"
|
|
|
|
VER = "0"
|
|
do_compile () {
|
|
${CC} -I${S} -fPIC -shared -o libfts.so.${VER} -Wl,-soname,libfts.so.${VER} ${S}/fts.c
|
|
}
|
|
|
|
do_install() {
|
|
install -Dm755 ${B}/libfts.so.${VER} ${D}${libdir}/libfts.so.${VER}
|
|
ln -sf libfts.so.${VER} ${D}${libdir}/libfts.so
|
|
install -Dm644 ${S}/fts.h ${D}${includedir}/fts.h
|
|
}
|
|
#
|
|
# We will skip parsing for non-musl systems
|
|
#
|
|
COMPATIBLE_HOST = ".*-musl.*"
|
|
|