mirror of
https://git.yoctoproject.org/poky
synced 2026-02-10 10:43:02 +01:00
603b4de33a
LTO support was removed from Cairo in 1.12.18 (and 1.14.0). https://bugs.freedesktop.org/show_bug.cgi?id=77060 http://cgit.freedesktop.org/cairo/commit/?h=1.12&id=213b3b9b8b92944506c712aa4d728903c547f879 (From OE-Core rev: cedc94919995473ba67968a9115023d6061ab045) Signed-off-by: Andre McCurdy <armccurdy@gmail.com> Signed-off-by: Ross Burton <ross.burton@intel.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
47 lines
1.9 KiB
PHP
47 lines
1.9 KiB
PHP
SUMMARY = "The Cairo 2D vector graphics library"
|
|
DESCRIPTION = "Cairo is a multi-platform library providing anti-aliased \
|
|
vector-based rendering for multiple target backends. Paths consist \
|
|
of line segments and cubic splines and can be rendered at any width \
|
|
with various join and cap styles. All colors may be specified with \
|
|
optional translucence (opacity/alpha) and combined using the \
|
|
extended Porter/Duff compositing algebra as found in the X Render \
|
|
Extension."
|
|
HOMEPAGE = "http://cairographics.org"
|
|
BUGTRACKER = "http://bugs.freedesktop.org"
|
|
SECTION = "libs"
|
|
|
|
LICENSE = "MPL-1 & LGPLv2.1 & GPLv3+"
|
|
LICENSE_${PN} = "MPL-1 & LGPLv2.1"
|
|
LICENSE_${PN}-dev = "MPL-1 & LGPLv2.1"
|
|
LICENSE_${PN}-gobject = "MPL-1 & LGPLv2.1"
|
|
LICENSE_${PN}-script-interpreter = "MPL-1 & LGPLv2.1"
|
|
LICENSE_${PN}-perf-utils = "GPLv3+"
|
|
|
|
X11DEPENDS = "virtual/libx11 libsm libxrender libxext"
|
|
DEPENDS = "libpng fontconfig pixman glib-2.0 zlib"
|
|
|
|
PACKAGECONFIG ??= "${@bb.utils.contains('DISTRO_FEATURES', 'x11', 'x11 xcb', '', d)} \
|
|
${@bb.utils.contains('DISTRO_FEATURES', 'directfb', 'directfb', '', d)}"
|
|
|
|
PACKAGECONFIG[x11] = "--with-x=yes -enable-xlib,--with-x=no --disable-xlib,${X11DEPENDS}"
|
|
PACKAGECONFIG[xcb] = "--enable-xcb,--disable-xcb,libxcb"
|
|
PACKAGECONFIG[directfb] = "--enable-directfb=yes,,directfb"
|
|
PACKAGECONFIG[valgrind] = "--enable-valgrind=yes,--disable-valgrind,valgrind"
|
|
PACKAGECONFIG[egl] = "--enable-egl=yes,--disable-egl,virtual/egl"
|
|
PACKAGECONFIG[glesv2] = "--enable-glesv2,--disable-glesv2,virtual/libgles2"
|
|
|
|
#check for TARGET_FPU=soft and inform configure of the result so it can disable some floating points
|
|
require cairo-fpu.inc
|
|
EXTRA_OECONF += "${@get_cairo_fpu_setting(bb, d)} \
|
|
--enable-tee \
|
|
"
|
|
|
|
inherit autotools pkgconfig
|
|
|
|
# We don't depend on binutils so we need to disable this
|
|
export ac_cv_lib_bfd_bfd_openr="no"
|
|
# Ensure we don't depend on LZO
|
|
export ac_cv_lib_lzo2_lzo2a_decompress="no"
|
|
|
|
BBCLASSEXTEND = "native"
|