mirror of
https://git.yoctoproject.org/poky
synced 2026-02-10 18:53:13 +01:00
548d4332e8
Although the gold linker problems with DirectFB have only so far been observed with armv7a, they could potentially affect future arm targets too. Since there's no particular downside to using the bfd linker for DirectFB, apply the workaround to all arm targets. (From OE-Core rev: 82423662e297137657d67d272276a823cf3f3d4e) Signed-off-by: Andre McCurdy <armccurdy@gmail.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
77 lines
2.6 KiB
PHP
77 lines
2.6 KiB
PHP
SUMMARY = "Graphics abstraction library for the Linux Framebuffer Device"
|
|
DESCRIPTION = "DirectFB is a thin library that provides developers \
|
|
with hardware graphics acceleration, input device handling and \
|
|
abstraction, an integrated windowing system with support for \
|
|
translucent windows and multiple display layers on top of the \
|
|
Linux framebuffer device."
|
|
SECTION = "libs"
|
|
LICENSE = "LGPLv2.1"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=dcf3c825659e82539645da41a7908589"
|
|
|
|
HOMEPAGE = "http://directfb.org"
|
|
DEPENDS = "jpeg libpng freetype zlib tslib sysfsutils"
|
|
|
|
SRC_URI = "http://www.directfb.org/downloads/Core/DirectFB-1.7/DirectFB-${PV}.tar.gz \
|
|
file://configurefix.patch \
|
|
file://fusion.patch \
|
|
file://bashism.patch \
|
|
file://0001-gfx-direct-Aboid-usng-VLAs-and-printf-formats.patch \
|
|
"
|
|
|
|
S = "${WORKDIR}/DirectFB-${PV}"
|
|
|
|
LDFLAGS_append =" -lts -lm"
|
|
|
|
# Workaround for linking issues seen with armv7a + gold
|
|
LDFLAGS_append_arm = "${@base_contains('DISTRO_FEATURES', 'ld-is-gold', ' -fuse-ld=bfd ', '', d)}"
|
|
|
|
BINCONFIG = "${bindir}/directfb-config"
|
|
|
|
inherit autotools binconfig-disabled pkgconfig
|
|
|
|
PACKAGECONFIG ??= ""
|
|
PACKAGECONFIG[jpeg2000] = "--enable-jpeg2000,--disable-jpeg2000,jasper"
|
|
PACKAGECONFIG[drmkms] = "--enable-drmkms,--disable-drmkms,libdrm"
|
|
PACKAGECONFIG[tiff] = "--enable-tiff,--disable-tiff,tiff"
|
|
PACKAGECONFIG[webp] = "--enable-webp,--disable-webp,libwebp"
|
|
|
|
EXTRA_OECONF = "\
|
|
--with-gfxdrivers=none \
|
|
--enable-freetype=yes \
|
|
--enable-zlib \
|
|
--disable-imlib2 \
|
|
--disable-mesa \
|
|
--disable-sdl \
|
|
--disable-vnc \
|
|
--disable-x11 \
|
|
"
|
|
|
|
#Once -fno-omit-frame-pointer option of gcc is added into TARGET_CLFAGS as default
|
|
#this will cause directfb build failure on x86 arch, so filter out it.
|
|
TARGET_CFLAGS_remove_x86 = "-fno-omit-frame-pointer"
|
|
|
|
#PACKAGES_DYNAMIC += "^directfb-inputdrivers-.*"
|
|
#
|
|
#python populate_packages_prepend () {
|
|
# inputdrivers_libdir = d.expand('${libdir}/directfb-${RV}/inputdrivers')
|
|
# do_split_packages(d, inputdrivers_libdir, '*.so$', 'directfb-inputdrivers-%s', 'Directfb plugin for %s')
|
|
#}
|
|
|
|
# NOTE: monolithic packaging for now, should improve that eventually
|
|
|
|
FILES_${PN}-dev += "\
|
|
${bindir}/directfb-config \
|
|
${libdir}/directfb-${RV}/systems/*.la \
|
|
${libdir}/directfb-${RV}/inputdrivers/*.la \
|
|
${libdir}/directfb-${RV}/interfaces/*/*.la \
|
|
${libdir}/directfb-${RV}/wm/*.la \
|
|
"
|
|
|
|
FILES_${PN} += "\
|
|
${libdir}/directfb-${RV}/systems/*.so \
|
|
${libdir}/directfb-${RV}/inputdrivers/*.so \
|
|
${libdir}/directfb-${RV}/interfaces/*/*.so \
|
|
${libdir}/directfb-${RV}/wm/*.so \
|
|
${datadir}/directfb-${PV} \
|
|
"
|