mirror of
https://git.yoctoproject.org/poky
synced 2026-02-10 10:43:02 +01:00
8dd27efecf
Calibration acquires a default resolution of 1280x1024 when running xinput_calibrator_pointercal.sh, obtain correct screen resolution by using xrandr to grab user-specified geometry and pass to script (From OE-Core rev: ce6f15dc3905ab0b061b20cc35fd179fdd9e070f) Signed-off-by: Jonathan David <jonathan.david@ni.com> Signed-off-by: Ross Burton <ross.burton@intel.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
39 lines
1.4 KiB
BlitzBasic
39 lines
1.4 KiB
BlitzBasic
SUMMARY = "Touchscreen calibration program for X11"
|
|
HOMEPAGE = "http://www.freedesktop.org/wiki/Software/xinput_calibrator"
|
|
LICENSE = "MIT-X"
|
|
LIC_FILES_CHKSUM = "file://src/calibrator.cpp;endline=22;md5=1bcba08f67cdb56f34021557898e4b5a"
|
|
DEPENDS = "virtual/libx11 libxi"
|
|
|
|
PV = "0.7.5+git${SRCPV}"
|
|
PR = "r6"
|
|
|
|
inherit autotools pkgconfig distro_features_check
|
|
# depends on virtual/libx11
|
|
REQUIRED_DISTRO_FEATURES = "x11"
|
|
|
|
SRCREV = "c01c5af807cb4b0157b882ab07a893df9a810111"
|
|
SRC_URI = "git://github.com/tias/xinput_calibrator.git \
|
|
file://30xinput_calibrate.sh \
|
|
file://Allow-xinput_calibrator_pointercal.sh-to-be-run-as-n.patch \
|
|
file://add-geometry-input-when-calibrating.patch"
|
|
|
|
S = "${WORKDIR}/git"
|
|
|
|
# force native X11 ui as we don't have gtk+ in DEPENDS
|
|
EXTRA_OECONF += "--with-gui=x11"
|
|
|
|
do_install_append() {
|
|
install -d ${D}${bindir}
|
|
install -m 0755 ${S}/scripts/xinput_calibrator_pointercal.sh ${D}${bindir}/xinput_calibrator_once.sh
|
|
|
|
install -d ${D}${sysconfdir}/X11/Xsession.d/
|
|
install -m 0755 ${WORKDIR}/30xinput_calibrate.sh ${D}${sysconfdir}/X11/Xsession.d/
|
|
|
|
install -d ${D}${sysconfdir}/xdg/autostart
|
|
sed -e 's,^Exec=.*,Exec=${bindir}/xinput_calibrator_once.sh,' ${S}/scripts/xinput_calibrator.desktop > ${D}${sysconfdir}/xdg/autostart/xinput_calibrator.desktop
|
|
}
|
|
|
|
FILES_${PN} += "${sysconfdir}/xdg/autostart"
|
|
RDEPENDS_${PN} = "xinput formfactor"
|
|
RRECOMMENDS_${PN} = "pointercal-xinput"
|