mirror of
https://git.yoctoproject.org/poky
synced 2026-02-14 04:33:03 +01:00
d6e7b5b1b1
The Xorg libraries use REQUIRED_DISTRO_FEATURES to stop building on distributions without the x11 feature but this stops people building native tooling that uses libX11, such as libsdl-native. (From OE-Core rev: 161bb3409edee21827cf594cc011fe88185f1496) Signed-off-by: Ross Burton <ross.burton@intel.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
37 lines
1.3 KiB
BlitzBasic
37 lines
1.3 KiB
BlitzBasic
SUMMARY = "XCB: The X protocol C binding library"
|
|
DESCRIPTION = "The X protocol C-language Binding (XCB) is a replacement \
|
|
for Xlib featuring a small footprint, latency hiding, direct access to \
|
|
the protocol, improved threading support, and extensibility."
|
|
HOMEPAGE = "http://xcb.freedesktop.org"
|
|
BUGTRACKER = "https://bugs.freedesktop.org/enter_bug.cgi?product=XCB"
|
|
SECTION = "x11/libs"
|
|
|
|
LICENSE = "MIT"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=d763b081cb10c223435b01e00dc0aba7"
|
|
|
|
SRC_URI = "http://xcb.freedesktop.org/dist/libxcb-${PV}.tar.bz2 \
|
|
file://xcbincludedir.patch \
|
|
file://disable-check.patch \
|
|
file://gcc-mips-pr68302-mips-workaround.patch \
|
|
"
|
|
SRC_URI[md5sum] = "f97a65e6158775de518ac391935634c2"
|
|
SRC_URI[sha256sum] = "b720fd6c7d200e5371affdb3f049cc8f88cff9aed942ff1b824d95eedbf69d30"
|
|
|
|
BBCLASSEXTEND = "native nativesdk"
|
|
|
|
DEPENDS = "xcb-proto xproto libxau libpthread-stubs libxdmcp"
|
|
|
|
PACKAGES_DYNAMIC = "^libxcb-.*"
|
|
|
|
FILES_${PN} = "${libdir}/libxcb.so.*"
|
|
|
|
inherit autotools pkgconfig distro_features_check
|
|
|
|
# The libxau and others requires x11 in DISTRO_FEATURES
|
|
REQUIRED_DISTRO_FEATURES = "x11"
|
|
REQUIRED_DISTRO_FEATURES_class-native = ""
|
|
|
|
python populate_packages_prepend () {
|
|
do_split_packages(d, '${libdir}', '^libxcb-(.*)\.so\..*$', 'libxcb-%s', 'XCB library module for %s', allow_links=True)
|
|
}
|