mirror of
https://git.yoctoproject.org/poky
synced 2026-02-09 18:23:02 +01:00
b5b3085d9d
* Remove backport patch filemode-fix.patch.
* Update --with-kernel=${STAGING_DIR_HOST}/${prefix} to find kernel
headers (linux/*.h) to fix the error:
| checking kernel supports perf_events... unknown -- perf_event.h not found
| ERROR: You requested to build oprofile with '--with-kernel=/buildarea/lyang1/test_f2/tmp/work-shared/qemux86/kernel-source',
| but headers were not accessible at the given location.
| Be sure you have run the following command from within your kernel source tree:
| make headers_install INSTALL_HDR_PATH=<kernel-hdrs-install-dir>
| Then pass <kernel-hdrs-install-dir> to oprofile's '--with-kernel' configure option.
| configure: error: Unable to build oprofile. Exiting.
(From OE-Core rev: b2200152deef0aec3cd8fe55bb73d6e8fccfe159)
(From OE-Core rev: 2dff13e834dc7b67e16ee597d7f9a3efdc72d10f)
Signed-off-by: Robert Yang <liezhi.yang@windriver.com>
Signed-off-by: Ross Burton <ross.burton@intel.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
59 lines
2.0 KiB
PHP
59 lines
2.0 KiB
PHP
SUMMARY = "System-Wide Profiler"
|
|
DESCRIPTION = "OProfile is a system-wide profiler for Linux systems, capable \
|
|
of profiling all running code at low overhead."
|
|
HOMEPAGE = "http://oprofile.sourceforge.net/news/"
|
|
BUGTRACKER = "http://sourceforge.net/tracker/?group_id=16191&atid=116191"
|
|
|
|
LICENSE = "LGPLv2.1+ & GPLv2"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=94d55d512a9ba36caa9b7df079bae19f \
|
|
file://libopagent/opagent.h;beginline=5;endline=26;md5=4f16f72c7a493d8a4704aa18d03d15c6 \
|
|
"
|
|
SECTION = "devel"
|
|
|
|
DEPENDS = "popt binutils"
|
|
RDEPENDS_${PN} = "binutils-symlinks"
|
|
RRECOMMENDS_${PN} = "kernel-vmlinux"
|
|
|
|
FILES_${PN} = "${bindir} ${libdir}/${BPN}/lib*${SOLIBS} ${datadir}/${BPN}"
|
|
FILES_${PN}-dev += "${libdir}/${BPN}/lib*${SOLIBSDEV} ${libdir}/${BPN}/lib*.la"
|
|
FILES_${PN}-staticdev += "${libdir}/${BPN}/lib*.a"
|
|
|
|
SRC_URI = "${SOURCEFORGE_MIRROR}/${BPN}/${BPN}-${PV}.tar.gz \
|
|
file://acinclude.m4 \
|
|
file://automake-foreign.patch \
|
|
file://oprofile-cross-compile-tests.patch \
|
|
file://run-ptest \
|
|
file://root-home-dir.patch"
|
|
|
|
inherit autotools pkgconfig ptest
|
|
|
|
EXTRA_OECONF = "--with-kernel=${STAGING_DIR_HOST}${prefix} --without-x ac_cv_prog_XSLTPROC="
|
|
do_configure () {
|
|
cp ${WORKDIR}/acinclude.m4 ${S}/
|
|
autotools_do_configure
|
|
}
|
|
|
|
EXTRA_OEMAKE = "SRCDIR=${PTEST_PATH}/libutil++/tests"
|
|
do_compile_ptest() {
|
|
oe_runmake check
|
|
}
|
|
|
|
do_install_ptest() {
|
|
subdirs="libdb/tests libutil++/tests libregex/tests libutil/tests libop/tests libdb/tests "
|
|
for tooltest in ${subdirs}
|
|
do
|
|
find ${tooltest} -perm /u=x -type f| cpio -pvdu ${D}${PTEST_PATH}
|
|
done
|
|
|
|
# needed by some libop tests
|
|
cp -r events ${D}${PTEST_PATH}
|
|
|
|
# needed by libregex regex_test
|
|
cp libregex/stl.pat ${D}${PTEST_PATH}/libregex
|
|
cp libregex/tests/mangled-name ${D}${PTEST_PATH}/libregex/tests
|
|
|
|
# needed by litutil++ file_manip_tests
|
|
cp ${S}/libutil++/tests/file_manip_tests.cpp \
|
|
libutil++/tests/file_manip_tests.o ${D}${PTEST_PATH}/libutil++/tests
|
|
}
|