mirror of
https://git.yoctoproject.org/poky
synced 2026-02-10 10:43:02 +01:00
6752484aff
Handle renaming of the HLS plugin: http://cgit.freedesktop.org/gstreamer/gst-plugins-bad/commit/?id=efe62292a3d045126654d93239fdf4cc8e48ae08 Switch AES decryption for the HLS plugin from nettle to openssl. The autogen.sh script takes care of cd'ing to the correct directory before it does anything, so we don't need to cd on its behalf any more in do_configure_prepend(). http://cgit.freedesktop.org/gstreamer/gst-plugins-bad/tree/autogen.sh?id=1.7.1 (From OE-Core rev: e91f29fb360b022cb3eaba9c2b09c247677961d8) Signed-off-by: Andre McCurdy <armccurdy@gmail.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
46 lines
1.9 KiB
BlitzBasic
46 lines
1.9 KiB
BlitzBasic
DEFAULT_PREFERENCE = "-1"
|
|
|
|
include gstreamer1.0-plugins-bad.inc
|
|
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=73a5855a8119deb017f5f13cf327095d \
|
|
file://COPYING.LIB;md5=21682e4e8fea52413fd26c60acb907e5 \
|
|
file://gst/tta/crc32.h;beginline=12;endline=29;md5=27db269c575d1e5317fffca2d33b3b50 \
|
|
file://gst/tta/filters.h;beginline=12;endline=29;md5=8a08270656f2f8ad7bb3655b83138e5a"
|
|
|
|
SRC_URI = " \
|
|
git://anongit.freedesktop.org/gstreamer/gst-plugins-bad;name=base \
|
|
git://anongit.freedesktop.org/gstreamer/common;destsuffix=git/common;name=common \
|
|
file://configure-allow-to-disable-libssh2.patch \
|
|
"
|
|
|
|
PV = "1.7.1+git${SRCPV}"
|
|
|
|
SRCREV_base = "3a088ecc9330d5cb8888ff43de0fe4f61c23a607"
|
|
SRCREV_common = "86e46630ed8af8d94796859db550a9c3d89c9f65"
|
|
SRCREV_FORMAT = "base"
|
|
|
|
S = "${WORKDIR}/git"
|
|
|
|
# over-ride the default hls PACKAGECONFIG in gstreamer1.0-plugins-bad.inc to
|
|
# pass an additional --with-hls-crypto=XXX option (new in 1.7.x) and switch HLS
|
|
# AES decryption from nettle to openssl (ie a shared dependency with dtls).
|
|
# This should move back to the common .inc once the main recipe updates to 1.8.x
|
|
PACKAGECONFIG[hls] = "--enable-hls --with-hls-crypto=openssl,--disable-hls,openssl"
|
|
|
|
do_configure_prepend() {
|
|
${S}/autogen.sh --noconfigure
|
|
}
|
|
|
|
# In 1.6.2, the "--enable-hls" configure option generated an installable package
|
|
# called "gstreamer1.0-plugins-bad-fragmented". In 1.7.1 that HLS plugin package
|
|
# has become "gstreamer1.0-plugins-bad-hls". See:
|
|
# http://cgit.freedesktop.org/gstreamer/gst-plugins-bad/commit/?id=efe62292a3d045126654d93239fdf4cc8e48ae08
|
|
|
|
PACKAGESPLITFUNCS_append = " handle_hls_rename "
|
|
|
|
python handle_hls_rename () {
|
|
d.setVar('RPROVIDES_gstreamer1.0-plugins-bad-hls', 'gstreamer1.0-plugins-bad-fragmented')
|
|
d.setVar('RREPLACES_gstreamer1.0-plugins-bad-hls', 'gstreamer1.0-plugins-bad-fragmented')
|
|
d.setVar('RCONFLICTS_gstreamer1.0-plugins-bad-hls', 'gstreamer1.0-plugins-bad-fragmented')
|
|
}
|