mirror of
https://git.yoctoproject.org/poky
synced 2026-02-09 18:23:02 +01:00
103f0e5828
Disable RPM signature validation so that it is possible to create package feeds of signed RPM packages without importing the public part of the signing key into the RPM database. In any case, the signatures are validated when the packages in the feed are used (e.g. in image generation of manually installing packages from the feed). The original idea idea of this patch is from Mark Hatle <mark.hatle@windriver.com>. [YOCTO #8134] (From OE-Core rev: c419c64c30736ecc7b496161b4f9d9f3cc88102f) Signed-off-by: Markus Lehtonen <markus.lehtonen@linux.intel.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
51 lines
1.8 KiB
BlitzBasic
51 lines
1.8 KiB
BlitzBasic
SUMMARY = "Creates metadata indexes for RPM package repositories"
|
|
HOMEPAGE = "http://createrepo.baseurl.org/"
|
|
|
|
RECIPE_NO_UPDATE_REASON = "Versions after 0.9.* use YUM, so we hold at 0.4.11"
|
|
|
|
LICENSE = "GPLv2+"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=18810669f13b87348459e611d31ab760"
|
|
|
|
DEPENDS_class-native += "libxml2-native rpm-native"
|
|
RDEPENDS_${PN}_class-target = "libxml2-python"
|
|
|
|
PR = "r9"
|
|
|
|
SRC_URI = "http://createrepo.baseurl.org/download/${BP}.tar.gz \
|
|
file://fix-native-install.patch \
|
|
file://python-scripts-should-use-interpreter-from-env.patch \
|
|
file://createrepo-rpm549.patch \
|
|
file://recommends.patch \
|
|
file://createrepo-dbpath.patch \
|
|
file://dumpMetadata-disable-signature-validation.patch \
|
|
file://rpm-createsolvedb.py \
|
|
"
|
|
|
|
SRC_URI[md5sum] = "3e9ccf4abcffe3f49af078c83611eda2"
|
|
SRC_URI[sha256sum] = "a73ae11a0dcde8bde36d900bc3f7f8f1083ba752c70a5c61b72d1e1e7608f21b"
|
|
|
|
BBCLASSEXTEND = "native"
|
|
|
|
do_install () {
|
|
oe_runmake -e 'DESTDIR=${D}' install
|
|
install -m 0755 ${WORKDIR}/rpm-createsolvedb.py ${D}${bindir}/
|
|
}
|
|
|
|
# Wrap the python script since the native python is
|
|
# ${bindir}/python-native/python, and the "#! /usr/bin/env python" can't
|
|
# find it since it is not in PATH.
|
|
do_install_append_class-native () {
|
|
# Not all the python scripts should be wrapped since some of
|
|
# them are modules (be imported).
|
|
for i in ${D}${datadir}/createrepo/genpkgmetadata.py \
|
|
${D}${datadir}/createrepo/modifyrepo.py \
|
|
${D}${bindir}/rpm-createsolvedb.py ; do
|
|
sed -i -e 's|^#!.*/usr/bin/env python|#! /usr/bin/env nativepython|' $i
|
|
done
|
|
|
|
create_wrapper ${D}/${bindir}/createrepo \
|
|
RPM_USRLIBRPM=${STAGING_LIBDIR_NATIVE}/rpm \
|
|
RPM_ETCRPM=${STAGING_ETCDIR_NATIVE}/rpm \
|
|
RPM_LOCALEDIRRPM=${STAGING_DATADIR_NATIVE}/locale
|
|
}
|