mirror of
https://git.yoctoproject.org/poky
synced 2026-02-20 08:29:42 +01:00
4e38304d6c
for SDK they are provided via nativesdk-binutils latest binutils have started to build libdep plugin as static library libdep.a which is then reported via build QA ERROR: QA Issue: non -staticdev package contains static .a library: binutils-cross-canadian-aarch64 path '/usr/local/oe-sdk-hardcoded-buildpath/sysroots/x86_64-oesdk-linux/usr/lib/aarch64-oe-linux/bfd-plugins/libdep.a' [staticdev] (From OE-Core rev: c871ad4ee62594c05d34b6ed2543d804a4ece07d) Signed-off-by: Khem Raj <raj.khem@gmail.com> Signed-off-by: Mathieu Dubois-Briand <mathieu.dubois-briand@bootlin.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
39 lines
1.3 KiB
PHP
39 lines
1.3 KiB
PHP
inherit cross-canadian
|
|
|
|
SUMMARY = "GNU binary utilities (cross-canadian for ${TARGET_ARCH} target)"
|
|
PN = "binutils-cross-canadian-${TRANSLATED_TARGET_ARCH}"
|
|
BPN = "binutils"
|
|
|
|
DEPENDS = "flex-native bison-native virtual/nativesdk-cross-cc virtual/nativesdk-libc nativesdk-zlib nativesdk-gettext nativesdk-flex"
|
|
EXTRA_OECONF += "--with-sysroot=${SDKPATH}/sysroots/${TUNE_PKGARCH}${TARGET_VENDOR}-${TARGET_OS} \
|
|
--enable-poison-system-directories \
|
|
"
|
|
|
|
# We have to point binutils at a sysroot but we don't need to rebuild if this changes
|
|
# e.g. we switch between different machines with different tunes.
|
|
EXTRA_OECONF[vardepsexclude] = "TUNE_PKGARCH"
|
|
|
|
# lld complains
|
|
# aarch64-yoesdk-linux-ld.lld: error: version script assignment of 'GLIBC_2.0' to symbol 'dlclose' failed: symbol not defined
|
|
|
|
LDFLAGS:append:toolchain-clang = " -fuse-ld=bfd"
|
|
|
|
do_install () {
|
|
autotools_do_install
|
|
|
|
# We're not interested in the plugins, libs, or headers, these would come from the
|
|
# nativesdk or target version of the binutils recipe
|
|
rm -rf ${D}${prefix}/${TARGET_SYS}
|
|
rm -rf ${D}${libdir}/bfd-plugins
|
|
rm -f ${D}${libdir}/libbfd*
|
|
rm -f ${D}${libdir}/libiberty*
|
|
rm -f ${D}${libdir}/libopcodes*
|
|
rm -f ${D}${includedir}/*.h
|
|
rm -f ${D}${sysconfdir}/gprofng.rc
|
|
rmdir ${D}${sysconfdir} || :
|
|
|
|
cross_canadian_bindirlinks
|
|
}
|
|
|
|
BBCLASSEXTEND = ""
|