mirror of
https://git.yoctoproject.org/poky
synced 2026-02-05 16:28:43 +01:00
51e75e216c
Release notes (https://github.com/numpy/numpy/releases/tag/v2.3.3): The NumPy 2.3.3 release is a patch release split between a number of maintenance updates and bug fixes. This release supports Python versions 3.11-3.14. Note that the 3.14.0 final is currently expected in Oct, 2025. This release is based on 3.14.0rc2. Reproducibility seems OK. ptests look OK: |============================================================================ |Testsuite summary |# TOTAL: 48954 |# PASS: 46490 |# SKIP: 2426 |# XFAIL: 33 |# FAIL: 0 |# XPASS: 5 |# ERROR: 0 |DURATION: 169 |END: /usr/lib/python3-numpy/ptest |2025-09-19T15:20 |STOP: ptest-runner |TOTAL: 1 FAIL: 0 (From OE-Core rev: d92db41f718a79ffd3ed173a46c5567fa002e7a7) Signed-off-by: Trevor Gamblin <tgamblin@baylibre.com> Signed-off-by: Mathieu Dubois-Briand <mathieu.dubois-briand@bootlin.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
80 lines
2.9 KiB
BlitzBasic
80 lines
2.9 KiB
BlitzBasic
SUMMARY = "A sophisticated Numeric Processing Package for Python"
|
|
HOMEPAGE = "https://numpy.org/"
|
|
DESCRIPTION = "NumPy is the fundamental package needed for scientific computing with Python."
|
|
SECTION = "devel/python"
|
|
LICENSE = "BSD-3-Clause & BSD-2-Clause & PSF-2.0 & Apache-2.0 & MIT"
|
|
LIC_FILES_CHKSUM = "file://LICENSE.txt;md5=26080bf81b2662c7119d3ef28ae197fd"
|
|
|
|
SRCNAME = "numpy"
|
|
|
|
SRC_URI = "${GITHUB_BASE_URI}/download/v${PV}/${SRCNAME}-${PV}.tar.gz \
|
|
file://0001-Don-t-search-usr-and-so-on-for-libraries-by-default-.patch \
|
|
file://fix_reproducibility.patch \
|
|
file://run-ptest \
|
|
"
|
|
SRC_URI[sha256sum] = "ddc7c39727ba62b80dfdbedf400d1c10ddfa8eefbd7ec8dcb118be8b56d31029"
|
|
|
|
GITHUB_BASE_URI = "https://github.com/numpy/numpy/releases"
|
|
UPSTREAM_CHECK_REGEX = "releases/tag/v?(?P<pver>\d+(\.\d+)+)$"
|
|
|
|
inherit pkgconfig ptest python_mesonpy github-releases cython
|
|
|
|
S = "${UNPACKDIR}/numpy-${PV}"
|
|
|
|
PACKAGECONFIG[svml] = "-Ddisable-svml=false,-Ddisable-svml=true"
|
|
|
|
# the overflow tests fail with compiler-rt on aarch64
|
|
LDFLAGS:append:toolchain-clang:aarch64 = " -rtlib=libgcc -unwindlib=libgcc"
|
|
|
|
# Remove references to buildpaths from numpy's __config__.py
|
|
do_install:append() {
|
|
sed -i \
|
|
-e 's|${S}=||g' \
|
|
-e 's|${B}=||g' \
|
|
-e 's|${RECIPE_SYSROOT_NATIVE}=||g' \
|
|
-e 's|${RECIPE_SYSROOT_NATIVE}||g' \
|
|
-e 's|${RECIPE_SYSROOT}=||g' \
|
|
-e 's|${RECIPE_SYSROOT}||g' ${D}${PYTHON_SITEPACKAGES_DIR}/numpy/__config__.py
|
|
|
|
nativepython3 -mcompileall -s ${D} ${D}${PYTHON_SITEPACKAGES_DIR}/numpy/__config__.py
|
|
}
|
|
|
|
FILES:${PN}-staticdev += "${PYTHON_SITEPACKAGES_DIR}/numpy/_core/lib/*.a \
|
|
${PYTHON_SITEPACKAGES_DIR}/numpy/random/lib/*.a \
|
|
"
|
|
|
|
# install what is needed for numpy.test()
|
|
RDEPENDS:${PN} = "\
|
|
python3-compression \
|
|
python3-ctypes \
|
|
python3-datetime \
|
|
python3-difflib \
|
|
python3-doctest \
|
|
python3-email \
|
|
python3-json \
|
|
python3-misc \
|
|
python3-mmap \
|
|
python3-multiprocessing \
|
|
python3-netclient \
|
|
python3-numbers \
|
|
python3-pickle \
|
|
python3-pkgutil \
|
|
python3-pprint \
|
|
python3-pydoc \
|
|
python3-shell \
|
|
python3-threading \
|
|
python3-unittest \
|
|
"
|
|
RDEPENDS:${PN}-ptest += "\
|
|
ldd \
|
|
meson \
|
|
python3-hypothesis \
|
|
python3-pytest \
|
|
python3-resource \
|
|
python3-sortedcontainers \
|
|
python3-typing-extensions \
|
|
python3-unittest-automake-output \
|
|
"
|
|
|
|
BBCLASSEXTEND = "native nativesdk"
|