mirror of
https://git.yoctoproject.org/poky
synced 2026-05-01 15:32:12 +02:00
a821638e78
Take an upstream patch to remove buildpaths from the generator's CMake files, so we don't need to sed them out. Also, the generator tool is only needed when cross-compiling libical, so we don't actually need to install it in the target package. This has the nice side-effect of removing libxml2 from the target RDEPENDS as it is only used in the tool. (From OE-Core rev: 01ac9719b32088a809ca1553fceba71cec31054d) Signed-off-by: Ross Burton <ross.burton@arm.com> Signed-off-by: Mathieu Dubois-Briand <mathieu.dubois-briand@bootlin.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
59 lines
2.9 KiB
BlitzBasic
59 lines
2.9 KiB
BlitzBasic
SUMMARY = "iCal and scheduling (RFC 2445, 2446, 2447) library"
|
|
DESCRIPTION = "An Open Source implementation of the iCalendar protocols \
|
|
and protocol data units. The iCalendar specification describes how \
|
|
calendar clients can communicate with calendar servers so users can store \
|
|
their calendar data and arrange meetings with other users. "
|
|
HOMEPAGE = "https://github.com/libical/libical"
|
|
BUGTRACKER = "https://github.com/libical/libical/issues"
|
|
LICENSE = "LGPL-2.1-only | MPL-2.0"
|
|
LIC_FILES_CHKSUM = "file://LICENSE;md5=1910a2a76ddf6a9ba369182494170d87 \
|
|
file://LICENSE.LGPL21.txt;md5=8f690bb538f4b301d931374a6eb864d0 \
|
|
file://LICENSE.MPL2.txt;md5=f75d2927d3c1ed2414ef72048f5ad640 \
|
|
"
|
|
SECTION = "libs"
|
|
|
|
SRC_URI = "${GITHUB_BASE_URI}/download/v${PV}/${BP}.tar.gz \
|
|
file://0001-cmake-Do-not-export-CC-into-gir-compiler.patch \
|
|
file://flags.patch \
|
|
"
|
|
SRC_URI[sha256sum] = "e73de92f5a6ce84c1b00306446b290a2b08cdf0a80988eca0a2c9d5c3510b4c2"
|
|
|
|
inherit cmake pkgconfig gobject-introspection vala github-releases
|
|
|
|
DEPENDS += "libical-native"
|
|
|
|
PACKAGECONFIG ??= "icu glib"
|
|
PACKAGECONFIG[bdb] = ",-DCMAKE_DISABLE_FIND_PACKAGE_BDB=True,db"
|
|
PACKAGECONFIG[glib] = "-DICAL_GLIB=True,-DICAL_GLIB=False,glib-2.0-native libxml2-native glib-2.0 libxml2"
|
|
# ICU is used for RSCALE (RFC7529) support
|
|
PACKAGECONFIG[icu] = ",-DCMAKE_DISABLE_FIND_PACKAGE_ICU=True,icu"
|
|
|
|
# No need to use perl-native, the host perl is sufficient.
|
|
EXTRA_OECMAKE += "-DPERL_EXECUTABLE=${HOSTTOOLS_DIR}/perl"
|
|
# Disable the test suite as we can't install it
|
|
EXTRA_OECMAKE += "-DLIBICAL_BUILD_TESTING=false"
|
|
# doc build fails with linker error (??) for libical-glib so disable it
|
|
EXTRA_OECMAKE += "-DICAL_BUILD_DOCS=false"
|
|
# gobject-introspection
|
|
EXTRA_OECMAKE:append:class-target = " -DGObjectIntrospection_COMPILER=${STAGING_BINDIR}/g-ir-compiler-wrapper"
|
|
EXTRA_OECMAKE:append:class-target = " -DGObjectIntrospection_SCANNER=${STAGING_BINDIR}/g-ir-scanner-wrapper"
|
|
EXTRA_OECMAKE += "-DVAPIGEN=${STAGING_BINDIR_NATIVE}/vapigen"
|
|
EXTRA_OECMAKE += "${@bb.utils.contains('GI_DATA_ENABLED', 'True', '-DGOBJECT_INTROSPECTION=ON -DICAL_GLIB_VAPI=ON', '-DGOBJECT_INTROSPECTION=OFF -DICAL_GLIB_VAPI=OFF', d)}"
|
|
EXTRA_OECMAKE:append:class-native = " -DGOBJECT_INTROSPECTION=OFF -DICAL_GLIB_VAPI=OFF"
|
|
|
|
# Tell the cross-libical where the tool it needs to build is
|
|
EXTRA_OECMAKE:append:class-target = " -DIMPORT_ICAL_GLIB_SRC_GENERATOR=${STAGING_LIBDIR_NATIVE}/cmake/LibIcal/IcalGlibSrcGenerator.cmake"
|
|
|
|
do_install:append () {
|
|
# Remove build host references (https://github.com/libical/libical/issues/532)
|
|
sed -i -e 's,${STAGING_LIBDIR},${libdir},g' ${D}${libdir}/cmake/LibIcal/LibIcalTargets.cmake
|
|
}
|
|
|
|
# This tool is only needed to cross-compile, delete it from the target packages
|
|
do_install:append:class-target() {
|
|
rm -f ${D}${libexecdir}/libical/ical-glib-src-generator
|
|
rm -f ${D}${libdir}/cmake/LibIcal/IcalGlibSrcGenerator*.cmake
|
|
}
|
|
|
|
BBCLASSEXTEND = "native"
|