mirror of
https://git.yoctoproject.org/poky
synced 2026-04-29 09:32:11 +02:00
f3ad36d15c
- Rebased fix-rs6000-crt0.patch - Patch fix_makefile_include_arm_h.patch is no longer required, the newlib header dependency has been fixed upstream at 26f9cfd7 - LICENSE checksum change due to: - Adding SPDX identifier - Deleted Phoenix Systems from License and updated each licenses numbers accordingly. - Add a dummy limits.h header, to make the improved preprocessor checks happy during configure. - Add a patch for libgloss to maintain current behavior of TCLIBC=newlib by making libgloss DEPEND on newlib and use its installed headers. - Switch to git fetcher to simplify fetching the sources and avoid future issues due to the way newlib release snapshots were being published. (From OE-Core rev: 1c9cbb27dfe37ca4574c4285fb03ce394dee5ed1) Signed-off-by: Alejandro Enedino Hernandez Samaniego <alejandro@enedino.org> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
62 lines
2.0 KiB
PHP
62 lines
2.0 KiB
PHP
SUMMARY = "Newlib is a C library intended for use on embedded systems"
|
|
HOMEPAGE = "https://sourceware.org/newlib/"
|
|
DESCRIPTION = "C library intended for use on embedded systems. It is a conglomeration of several library parts, all under free software licenses that make them easily usable on embedded products."
|
|
SECTION = "libs"
|
|
|
|
LICENSE = "GPL-2.0-only & LGPL-3.0-only & GPL-3.0-only & LGPL-2.0-only & BSD-2-Clause & BSD-3-Clause & TCL"
|
|
LIC_FILES_CHKSUM = " \
|
|
file://COPYING;md5=59530bdf33659b29e73d4adb9f9f6552 \
|
|
file://COPYING3.LIB;md5=6a6a8e020838b23406c81b19c1d46df6 \
|
|
file://COPYING3;md5=d32239bcb673463ab874e80d47fae504 \
|
|
file://COPYING.LIBGLOSS;md5=c0469b6ebb847a75781066be515f032d \
|
|
file://COPYING.LIB;md5=2d5025d4aa3495befef8f17206a5b0a1 \
|
|
file://COPYING.NEWLIB;md5=5a9d477b5f4eab20dccf655a77107a6e \
|
|
file://newlib/libc/posix/COPYRIGHT;md5=103468ff1982be840fdf4ee9f8b51bbf \
|
|
"
|
|
|
|
BASEVER = "4.3.0"
|
|
PV = "${BASEVER}+git${SRCPV}"
|
|
SRC_URI = "git://sourceware.org/git/newlib-cygwin.git;protocol=https;branch=main"
|
|
SRCREV="9e09d6ed83cce4777a5950412647ccc603040409"
|
|
|
|
INHIBIT_DEFAULT_DEPS = "1"
|
|
DEPENDS = "virtual/${TARGET_PREFIX}gcc"
|
|
|
|
S = "${WORKDIR}/git"
|
|
B = "${WORKDIR}/build"
|
|
|
|
## disable stdlib
|
|
TARGET_CC_ARCH:append = " -nostdlib"
|
|
|
|
EXTRA_OECONF = " \
|
|
--build=${BUILD_SYS} \
|
|
--target=${TARGET_SYS} \
|
|
--host=${HOST_SYS} \
|
|
--prefix=${prefix} \
|
|
--exec-prefix=${exec_prefix} \
|
|
--bindir=${bindir} \
|
|
--libdir=${libdir} \
|
|
--includedir=${includedir} \
|
|
--enable-languages=c \
|
|
--with-newlib \
|
|
--with-gnu-as \
|
|
--with-gnu-ld \
|
|
--disable-multilib \
|
|
--disable-newlib-supplied-syscalls \
|
|
"
|
|
|
|
do_configure[cleandirs] = "${B}"
|
|
|
|
# We need a dummy limits.h to pass preprocessor checks
|
|
do_configure:append(){
|
|
install -d ${STAGING_INCDIR}
|
|
touch ${STAGING_INCDIR}/limits.h
|
|
}
|
|
|
|
do_install() {
|
|
oe_runmake install DESTDIR='${D}'
|
|
}
|
|
|
|
COMPATIBLE_HOST:libc-musl:class-target = "null"
|
|
COMPATIBLE_HOST:libc-glibc:class-target = "null"
|