mirror of
https://git.yoctoproject.org/poky
synced 2026-04-27 03:32:12 +02:00
7d45877e26
Integrating the following commit(s) to linux-yocto/5.15:
b98d189df02c aufs: bugfix, umount passes NULL to ->parse_monolithic()
13b883cbbbd9 aufs standalone: cosmetic, missing copyright sentence
21f8b0d81898 aufs: 5.15.5-20220117 ---> 5.15.5-20220221
6199fd896645 aufs: tiny, headers after fs_context
8ddb40e31c29 aufs: fs_context 7/7, finally remount
69035f71c6fd aufs: fs_context 6/7, now mount
bc841b970697 aufs: fs_context 5/7, parse all other mount options
435188053da2 aufs: fs_context 4/7, parse xino options
9af1f1825cbd aufs: fs_context 3/7, parse the branch-management options
1c05eb767f8c aufs: fs_context 2/7, parse "br" mount option
a8488f603134 aufs: fs_context 1/7, skelton of the new shceme
8e32e0015564 aufs: pre fs_context, convert a static flag to a macro
f90cb4144aec aufs: pre fs_context, support the incomplete sb and sbinfo case
948762ef859c aufs: pre fs_context, convert the type of alloc_sbinfo()
77151a08776b aufs: 5.15.5-20211129 ---> 5.15.5-20220117
2539adbbbe1e aufs: 5.14-20211018 ---> 5.15.5-20211129
7d32b25193c4 aufs: for v5.15-rc1, sync_inode() is gone
66ec0c509225 aufs: for v5.15-rc1, new param 'rcu' for ->get_acl()
69709dc518cd aufs: for v5.15-rc1, no mand-lock anymore
ada8fe9543e5 aufs: 5.14-20210906 ---> 5.14-20211018
b77f7f3f394a Revert "aufs: adjust to v5.15 fs changes"
(From OE-Core rev: fda812765b9e88d5bdf0fa5684ff968f413ef35c)
Signed-off-by: Bruce Ashfield <bruce.ashfield@gmail.com>
Signed-off-by: Alexandre Belloni <alexandre.belloni@bootlin.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
71 lines
3.3 KiB
BlitzBasic
71 lines
3.3 KiB
BlitzBasic
KBRANCH ?= "v5.15/standard/base"
|
|
|
|
require recipes-kernel/linux/linux-yocto.inc
|
|
|
|
# board specific branches
|
|
KBRANCH:qemuarm ?= "v5.15/standard/arm-versatile-926ejs"
|
|
KBRANCH:qemuarm64 ?= "v5.15/standard/qemuarm64"
|
|
KBRANCH:qemumips ?= "v5.15/standard/mti-malta32"
|
|
KBRANCH:qemuppc ?= "v5.15/standard/qemuppc"
|
|
KBRANCH:qemuriscv64 ?= "v5.15/standard/base"
|
|
KBRANCH:qemuriscv32 ?= "v5.15/standard/base"
|
|
KBRANCH:qemux86 ?= "v5.15/standard/base"
|
|
KBRANCH:qemux86-64 ?= "v5.15/standard/base"
|
|
KBRANCH:qemumips64 ?= "v5.15/standard/mti-malta64"
|
|
|
|
SRCREV_machine:qemuarm ?= "b6fd1a7dd80a336567fa30c1d674f0d5df9af836"
|
|
SRCREV_machine:qemuarm64 ?= "387a676543764b59e38cf6b13d6474846fb07d78"
|
|
SRCREV_machine:qemumips ?= "7c084cf3a700f7a2c68c8909501f4d35b3215e40"
|
|
SRCREV_machine:qemuppc ?= "239f7c8f37bf9ade16325101df3c06a485ccc74e"
|
|
SRCREV_machine:qemuriscv64 ?= "c9f3902d8069e32a8928153a38d8f6115194d128"
|
|
SRCREV_machine:qemuriscv32 ?= "c9f3902d8069e32a8928153a38d8f6115194d128"
|
|
SRCREV_machine:qemux86 ?= "c9f3902d8069e32a8928153a38d8f6115194d128"
|
|
SRCREV_machine:qemux86-64 ?= "c9f3902d8069e32a8928153a38d8f6115194d128"
|
|
SRCREV_machine:qemumips64 ?= "a4805fe749c9c56d18a60b5378674760ef0e85ed"
|
|
SRCREV_machine ?= "c9f3902d8069e32a8928153a38d8f6115194d128"
|
|
SRCREV_meta ?= "7dd85143b4ed77bdcb6628ac8ea69917e1cd29e5"
|
|
|
|
# set your preferred provider of linux-yocto to 'linux-yocto-upstream', and you'll
|
|
# get the <version>/base branch, which is pure upstream -stable, and the same
|
|
# meta SRCREV as the linux-yocto-standard builds. Select your version using the
|
|
# normal PREFERRED_VERSION settings.
|
|
BBCLASSEXTEND = "devupstream:target"
|
|
SRCREV_machine:class-devupstream ?= "e29be6724adbc9c3126d2a9550ec21f927f22f6d"
|
|
PN:class-devupstream = "linux-yocto-upstream"
|
|
KBRANCH:class-devupstream = "v5.15/base"
|
|
|
|
# remap qemuarm to qemuarma15 for the 5.8 kernel
|
|
# KMACHINE:qemuarm ?= "qemuarma15"
|
|
|
|
SRC_URI = "git://git.yoctoproject.org/linux-yocto.git;name=machine;branch=${KBRANCH}; \
|
|
git://git.yoctoproject.org/yocto-kernel-cache;type=kmeta;name=meta;branch=yocto-5.15;destsuffix=${KMETA}"
|
|
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=6bc538ed5bd9a7fc9398086aedcd7e46"
|
|
LINUX_VERSION ?= "5.15.32"
|
|
|
|
DEPENDS += "${@bb.utils.contains('ARCH', 'x86', 'elfutils-native', '', d)}"
|
|
DEPENDS += "openssl-native util-linux-native"
|
|
DEPENDS += "gmp-native libmpc-native"
|
|
|
|
PV = "${LINUX_VERSION}+git${SRCPV}"
|
|
|
|
KMETA = "kernel-meta"
|
|
KCONF_BSP_AUDIT_LEVEL = "1"
|
|
|
|
KERNEL_DEVICETREE:qemuarmv5 = "versatile-pb.dtb"
|
|
|
|
COMPATIBLE_MACHINE = "qemuarm|qemuarmv5|qemuarm64|qemux86|qemuppc|qemuppc64|qemumips|qemumips64|qemux86-64|qemuriscv64|qemuriscv32"
|
|
|
|
# Functionality flags
|
|
KERNEL_EXTRA_FEATURES ?= "features/netfilter/netfilter.scc"
|
|
KERNEL_FEATURES:append = " ${KERNEL_EXTRA_FEATURES}"
|
|
KERNEL_FEATURES:append:qemuall=" cfg/virtio.scc features/drm-bochs/drm-bochs.scc"
|
|
KERNEL_FEATURES:append:qemux86=" cfg/sound.scc cfg/paravirt_kvm.scc"
|
|
KERNEL_FEATURES:append:qemux86-64=" cfg/sound.scc cfg/paravirt_kvm.scc"
|
|
KERNEL_FEATURES:append = " ${@bb.utils.contains("TUNE_FEATURES", "mx32", " cfg/x32.scc", "", d)}"
|
|
KERNEL_FEATURES:append = " ${@bb.utils.contains("DISTRO_FEATURES", "ptest", " features/scsi/scsi-debug.scc", "", d)}"
|
|
KERNEL_FEATURES:append = " ${@bb.utils.contains("DISTRO_FEATURES", "ptest", " features/gpio/mockup.scc", "", d)}"
|
|
|
|
INSANE_SKIP:kernel-vmlinux:qemuppc64 = "textrel"
|
|
|