mirror of
https://git.yoctoproject.org/poky
synced 2026-02-07 17:26:36 +01:00
d55b7650d3
We are experimenting some issues in the Autobuilder infraestructure possible due to high I/O loads, in order to provide more information about intervals of times in printk enable by default debug/printk.scc on qemu development images. [YOCTO #9299] (From OE-Core rev: dfa8be08aa6e7ad6dbc615df8875dc2ac1ac8946) Signed-off-by: Aníbal Limón <anibal.limon@linux.intel.com> Signed-off-by: Ross Burton <ross.burton@intel.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
61 lines
1.6 KiB
PHP
61 lines
1.6 KiB
PHP
SUMMARY = "Linux kernel"
|
|
SECTION = "kernel"
|
|
LICENSE = "GPLv2"
|
|
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=d7810fab7487fb0aad327b76f1be7cd7"
|
|
|
|
UPSTREAM_CHECK_GITTAGREGEX = "(?P<pver>\d+\.\d+(\.\d+)*)"
|
|
|
|
INC_PR = "r4"
|
|
|
|
DEPENDS += "xz-native bc-native"
|
|
DEPENDS_append_aarch64 = " libgcc"
|
|
KERNEL_CC_append_aarch64 = " ${TOOLCHAIN_OPTIONS}"
|
|
KERNEL_LD_append_aarch64 = " ${TOOLCHAIN_OPTIONS}"
|
|
|
|
DEPENDS_append_nios2 = " libgcc"
|
|
KERNEL_CC_append_nios2 = " ${TOOLCHAIN_OPTIONS}"
|
|
KERNEL_LD_append_nios2 = " ${TOOLCHAIN_OPTIONS}"
|
|
|
|
KERNEL_FEATURES_append_qemuall=" features/debug/printk.scc"
|
|
|
|
# A KMACHINE is the mapping of a yocto $MACHINE to what is built
|
|
# by the kernel. This is typically the branch that should be built,
|
|
# and it can be specific to the machine or shared
|
|
# KMACHINE = "UNDEFINED"
|
|
|
|
LINUX_KERNEL_TYPE ?= "standard"
|
|
|
|
# KMETA ?= ""
|
|
KBRANCH ?= "master"
|
|
KMACHINE ?= "${MACHINE}"
|
|
SRCREV_FORMAT ?= "meta_machine"
|
|
|
|
# LEVELS:
|
|
# 0: no reporting
|
|
# 1: report options that are specified, but not in the final config
|
|
# 2: report options that are not hardware related, but set by a BSP
|
|
KCONF_AUDIT_LEVEL ?= "1"
|
|
KCONF_BSP_AUDIT_LEVEL ?= "0"
|
|
KMETA_AUDIT ?= "yes"
|
|
|
|
LINUX_VERSION_EXTENSION ?= "-yocto-${LINUX_KERNEL_TYPE}"
|
|
|
|
# Pick up shared functions
|
|
inherit kernel
|
|
inherit kernel-yocto
|
|
require linux-dtb.inc
|
|
|
|
B = "${WORKDIR}/linux-${PACKAGE_ARCH}-${LINUX_KERNEL_TYPE}-build"
|
|
|
|
do_install_append(){
|
|
if [ -n "${KMETA}" ]; then
|
|
rm -rf ${STAGING_KERNEL_DIR}/${KMETA}
|
|
fi
|
|
}
|
|
|
|
# extra tasks
|
|
addtask kernel_link_images after do_compile before do_install
|
|
addtask validate_branches before do_patch after do_kernel_checkout
|
|
addtask kernel_configcheck after do_configure before do_compile
|