mirror of
https://git.yoctoproject.org/poky
synced 2026-02-06 00:38:45 +01:00
b77d5679c4
${libdir} is not applicable for the install path of perl-native files,
files are always installed to /usr/lib no matter the target is 32/64
bits. After installing, remove unpackaged and unneeded perl-native
files to prevent warnings.
Fix warning:
WARNING: For recipe git, the following files/directories were \
installed but not shipped in any package:
...
WARNING: /usr/lib/perl-native/perl/5.14.2/Git.pm
WARNING: /usr/lib/perl-native/perl/5.14.2/perllocal.pod
WARNING: /usr/lib/perl-native/perl/5.14.2/Error.pm
WARNING: /usr/lib/perl-native/perl/5.14.2/auto
[YOCTO#3780]
(From OE-Core rev: cc6b8261fa47a049e501882e9bfc40f61e603b6f)
Signed-off-by: Wenzong Fan <wenzong.fan@windriver.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
82 lines
2.2 KiB
PHP
82 lines
2.2 KiB
PHP
DESCRIPTION = "The git revision control system used by the Linux kernel developers"
|
|
SECTION = "console/utils"
|
|
LICENSE = "GPLv2"
|
|
DEPENDS = "openssl curl zlib expat"
|
|
|
|
PROVIDES_append_class-native = " git-replacement-native"
|
|
|
|
SRC_URI = "${KERNELORG_MIRROR}/software/scm/git/git-${PV}.tar.bz2 "
|
|
S = "${WORKDIR}/git-${PV}"
|
|
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=7c0d7ef03a7eb04ce795b0f60e68e7e1"
|
|
|
|
EXTRA_OECONF = "--with-perl=${STAGING_BINDIR_NATIVE}/perl-native/perl \
|
|
--without-tcltk \
|
|
"
|
|
|
|
inherit autotools perlnative
|
|
|
|
EXTRA_OEMAKE = "NO_PYTHON=1"
|
|
|
|
do_compile_prepend () {
|
|
# Remove perl/perl.mak to fix the out-of-date perl.mak error
|
|
# during rebuild
|
|
rm -f perl/perl.mak
|
|
}
|
|
|
|
do_install () {
|
|
oe_runmake install DESTDIR="${D}" bindir=${bindir} \
|
|
template_dir=${datadir}/git-core/templates \
|
|
GIT_PYTHON_DIR=${D}${datadir}/git-core/python
|
|
|
|
# ${libdir} is not applicable here, perl-native files are always
|
|
# installed to /usr/lib on both 32/64 bits targets.
|
|
rm -rf ${D}/usr/lib/perl-native
|
|
rmdir ${D}/usr/lib || true
|
|
}
|
|
|
|
do_install_append_class-native() {
|
|
create_wrapper ${D}/${bindir}/git \
|
|
GIT_EXEC_PATH=${libexecdir}/git-core \
|
|
GIT_TEMPLATE_DIR=${STAGING_DATADIR_NATIVE}/git-core/templates
|
|
}
|
|
|
|
FILES_${PN} += "${datadir}/git-core ${libxecdir}/git-core/"
|
|
FILES_${PN}-dbg += "${libexecdir}/git-core/.debug"
|
|
|
|
# Git tools requiring perl
|
|
PACKAGES =+ "${PN}-perltools"
|
|
FILES_${PN}-perltools += " \
|
|
${libexecdir}/git-core/git-add--interactive \
|
|
${libexecdir}/git-core/git-archimport \
|
|
${libexecdir}/git-core/git-cvsexportcommit \
|
|
${libexecdir}/git-core/git-cvsimport \
|
|
${libexecdir}/git-core/git-cvsserver \
|
|
${bindir}/git-cvsserver \
|
|
${libexecdir}/git-core/git-difftool \
|
|
${libexecdir}/git-core/git-relink \
|
|
${libexecdir}/git-core/git-send-email \
|
|
${libexecdir}/git-core/git-svn \
|
|
${datadir}/perl \
|
|
"
|
|
RDEPENDS_${PN}-perltools = "${PN} perl perl-module-file-path findutils"
|
|
|
|
PACKAGES =+ "${PN}-python"
|
|
FILES_${PN}-python = "${libdir}/python*"
|
|
|
|
|
|
# git-tk package with gitk and git-gui
|
|
PACKAGES =+ "${PN}-tk"
|
|
#RDEPENDS_${PN}-tk = "${PN} tk tcl"
|
|
#EXTRA_OEMAKE = "TCL_PATH=${STAGING_BINDIR_CROSS}/tclsh"
|
|
FILES_${PN}-tk = " \
|
|
${bindir}/gitk \
|
|
${datadir}/gitk \
|
|
"
|
|
|
|
PACKAGES =+ "gitweb"
|
|
FILES_gitweb = "${datadir}/gitweb/"
|
|
|
|
|
|
BBCLASSEXTEND = "native"
|