mirror of
https://git.yoctoproject.org/poky
synced 2026-02-11 11:13:04 +01:00
280374fa1c
* it's not part of sources, downloading some html from web is not better check then using meta/files/common-licenses/EPL-1.0 * http://www.eclipse.org/org/documents/epl-v10.html was changed, plain text looks the same, but html formating was changed (from MS Word export to valid XHTML 1.0, changing checksums for this new html would cause issues for people with old epl-v10.html already on PREMIRROR, so lets just remove it. (From OE-Core rev: 22bce79652fc753a7b5d536664b744e110b5775a) Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
47 lines
1.3 KiB
BlitzBasic
47 lines
1.3 KiB
BlitzBasic
DESCRIPTION = "Target Communication Framework"
|
|
HOMEPAGE = "http://wiki.eclipse.org/TCF"
|
|
BUGTRACKER = "https://bugs.eclipse.org/bugs/"
|
|
|
|
LICENSE = "EPL-1.0 | EDL-1.0"
|
|
LIC_FILES_CHKSUM = "file://edl-v10.html;md5=522a390a83dc186513f0500543ad3679"
|
|
|
|
SRCREV = "4ef94ecb927a8912c3d79ce137182247786cff8f"
|
|
PV = "0.4.0+git${SRCPV}"
|
|
PR = "r0"
|
|
|
|
SRC_URI = "git://git.eclipse.org/gitroot/tcf/org.eclipse.tcf.agent.git;protocol=git \
|
|
file://fix_ranlib.patch \
|
|
file://fix_tcf-agent.init.patch \
|
|
"
|
|
|
|
DEPENDS = "util-linux openssl"
|
|
RDEPENDS_${PN} = "bash"
|
|
|
|
S = "${WORKDIR}/git"
|
|
|
|
inherit update-rc.d
|
|
|
|
INITSCRIPT_NAME = "tcf-agent"
|
|
INITSCRIPT_PARAMS = "start 999 3 5 . stop 20 0 1 2 6 ."
|
|
|
|
# mangling needed for make
|
|
MAKE_ARCH = "`echo ${TARGET_ARCH} | sed s,i.86,i686,`"
|
|
MAKE_OS = "`echo ${TARGET_OS} | sed s,^linux.*,GNU/Linux,`"
|
|
|
|
EXTRA_OEMAKE = "MACHINE=${MAKE_ARCH} OPSYS=${MAKE_OS} 'CC=${CC}' 'AR=${AR}'"
|
|
|
|
# They don't build on ARM and we don't need them actually.
|
|
CFLAGS += "-DSERVICE_RunControl=0 -DSERVICE_Breakpoints=0 \
|
|
-DSERVICE_Memory=0 -DSERVICE_Registers=0 -DSERVICE_MemoryMap=0 \
|
|
-DSERVICE_StackTrace=0 -DSERVICE_Symbols=0 -DSERVICE_LineNumbers=0 \
|
|
-DSERVICE_Expressions=0"
|
|
|
|
do_compile() {
|
|
oe_runmake
|
|
}
|
|
|
|
do_install() {
|
|
oe_runmake install INSTALLROOT=${D}
|
|
}
|
|
|