mirror of
https://git.yoctoproject.org/poky
synced 2026-02-12 11:43:04 +01:00
fcf428cdb5
b24ef04ae libssh2: Fix build with autoconf 2.70+ d7aa71734 libssh2: enhance ptest b3e9b51c9 libssh2: fix ptest f5df715e2 libssh2: enable ptest c1d1697c5 libssh2: add nativesdk support 3a6cbf246 libssh2: Security Advisory - libssh2 - CVE-2019-17498 40ea4c939 libssh2: upgrade 1.8.2 -> 1.9.0 5a7e65cbf libssh2: Clarify BSD license variant (From OE-Core rev: 57df134b1be56a688f41851e5ff014dd859c0bc3) Signed-off-by: Randy MacLeod <Randy.MacLeod@windriver.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
54 lines
1.8 KiB
BlitzBasic
54 lines
1.8 KiB
BlitzBasic
SUMMARY = "A client-side C library implementing the SSH2 protocol"
|
|
HOMEPAGE = "http://www.libssh2.org/"
|
|
SECTION = "libs"
|
|
|
|
DEPENDS = "zlib"
|
|
|
|
LICENSE = "BSD-3-Clause"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=c5cf34fc0acb44b082ef50ef5e4354ca"
|
|
|
|
SRC_URI = "http://www.libssh2.org/download/${BP}.tar.gz \
|
|
file://CVE-2019-17498.patch \
|
|
file://0001-configure-Conditionally-undefine-backend-m4-macro.patch \
|
|
file://run-ptest \
|
|
"
|
|
|
|
SRC_URI_append_ptest = " file://0001-Don-t-let-host-enviroment-to-decide-if-a-test-is-bui.patch"
|
|
|
|
SRC_URI[md5sum] = "1beefafe8963982adc84b408b2959927"
|
|
SRC_URI[sha256sum] = "d5fb8bd563305fd1074dda90bd053fb2d29fc4bce048d182f96eaa466dfadafd"
|
|
|
|
inherit autotools pkgconfig ptest
|
|
|
|
EXTRA_OECONF += "\
|
|
--with-libz \
|
|
--with-libz-prefix=${STAGING_LIBDIR} \
|
|
"
|
|
|
|
# only one of openssl and gcrypt could be set
|
|
PACKAGECONFIG ??= "openssl"
|
|
PACKAGECONFIG[openssl] = "--with-crypto=openssl --with-libssl-prefix=${STAGING_LIBDIR}, , openssl"
|
|
PACKAGECONFIG[gcrypt] = "--with-crypto=libgcrypt --with-libgcrypt-prefix=${STAGING_EXECPREFIXDIR}, , libgcrypt"
|
|
|
|
BBCLASSEXTEND = "native nativesdk"
|
|
|
|
# required for ptest on documentation
|
|
RDEPENDS_${PN}-ptest = "man-db openssh"
|
|
RDEPENDS_${PN}-ptest_append_libc-glibc = " locale-base-en-us"
|
|
|
|
do_compile_ptest() {
|
|
sed -i "/\$(MAKE) \$(AM_MAKEFLAGS) check-TESTS/d" tests/Makefile
|
|
oe_runmake check
|
|
}
|
|
|
|
do_install_ptest() {
|
|
install -d ${D}${PTEST_PATH}/tests
|
|
install -m 0755 ${S}/test-driver ${D}${PTEST_PATH}/
|
|
cp -rf ${B}/tests/.libs/* ${D}${PTEST_PATH}/tests/
|
|
cp -rf ${S}/tests/mansyntax.sh ${D}${PTEST_PATH}/tests/
|
|
cp -rf ${S}/tests/ssh2.sh ${D}${PTEST_PATH}/tests/
|
|
cp -rf ${S}/tests/etc ${D}${PTEST_PATH}/tests/
|
|
mkdir -p ${D}${PTEST_PATH}/docs
|
|
cp -r ${S}/docs/* ${D}${PTEST_PATH}/docs/
|
|
}
|