mirror of
https://git.yoctoproject.org/poky
synced 2026-01-29 21:08:42 +01:00
bb0f9e8770
During testing of the v6.4 reference kernel, it was noticed that on-target modules no longer matched the magic value of the running kernel. This was due to a different localversion in the cross built kernel and the scripts / resources created on target. This was due to changes in the setlocalversion script introduced in the v6.3 series. The .scmversion file is no longer used (or packaged) to inhibit the addition of a "+" (through querying of the git status of the kernel) or the setting of a local version. We recently introduced the KERNEL_LOCALVERSION variable to allow recipes to place a value in .scmversion, so we extend the use of that variable to kernel-arch.bbclass and use it to set the exported variable LOCALVERSION. We must do it at the kernel-arch level, as the variable must be exported in any kernel build to ensure that setlocalversion always correctly sets the localversion. (From OE-Core rev: 765b13b7305c8d2f222cfc66d77c02e6a088c691) Signed-off-by: Bruce Ashfield <bruce.ashfield@gmail.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
90 lines
3.6 KiB
Plaintext
90 lines
3.6 KiB
Plaintext
#
|
|
# Copyright OpenEmbedded Contributors
|
|
#
|
|
# SPDX-License-Identifier: MIT
|
|
#
|
|
|
|
#
|
|
# set the ARCH environment variable for kernel compilation (including
|
|
# modules). return value must match one of the architecture directories
|
|
# in the kernel source "arch" directory
|
|
#
|
|
|
|
valid_archs = "alpha cris ia64 \
|
|
i386 x86 \
|
|
m68knommu m68k ppc powerpc powerpc64 ppc64 \
|
|
sparc sparc64 \
|
|
arm aarch64 \
|
|
m32r mips \
|
|
sh sh64 um h8300 \
|
|
parisc s390 v850 \
|
|
avr32 blackfin \
|
|
loongarch64 \
|
|
microblaze \
|
|
nios2 arc riscv xtensa"
|
|
|
|
def map_kernel_arch(a, d):
|
|
import re
|
|
|
|
valid_archs = d.getVar('valid_archs').split()
|
|
|
|
if re.match('(i.86|athlon|x86.64)$', a): return 'x86'
|
|
elif re.match('arceb$', a): return 'arc'
|
|
elif re.match('armeb$', a): return 'arm'
|
|
elif re.match('aarch64$', a): return 'arm64'
|
|
elif re.match('aarch64_be$', a): return 'arm64'
|
|
elif re.match('aarch64_ilp32$', a): return 'arm64'
|
|
elif re.match('aarch64_be_ilp32$', a): return 'arm64'
|
|
elif re.match('loongarch(32|64|)$', a): return 'loongarch'
|
|
elif re.match('mips(isa|)(32|64|)(r6|)(el|)$', a): return 'mips'
|
|
elif re.match('mcf', a): return 'm68k'
|
|
elif re.match('riscv(32|64|)(eb|)$', a): return 'riscv'
|
|
elif re.match('p(pc|owerpc)(|64)', a): return 'powerpc'
|
|
elif re.match('sh(3|4)$', a): return 'sh'
|
|
elif re.match('bfin', a): return 'blackfin'
|
|
elif re.match('microblazee[bl]', a): return 'microblaze'
|
|
elif a in valid_archs: return a
|
|
else:
|
|
if not d.getVar("TARGET_OS").startswith("linux"):
|
|
return a
|
|
bb.error("cannot map '%s' to a linux kernel architecture" % a)
|
|
|
|
export ARCH = "${@map_kernel_arch(d.getVar('TARGET_ARCH'), d)}"
|
|
|
|
def map_uboot_arch(a, d):
|
|
import re
|
|
|
|
if re.match('p(pc|owerpc)(|64)', a): return 'ppc'
|
|
elif re.match('i.86$', a): return 'x86'
|
|
return a
|
|
|
|
export UBOOT_ARCH = "${@map_uboot_arch(d.getVar('ARCH'), d)}"
|
|
|
|
# Set TARGET_??_KERNEL_ARCH in the machine .conf to set architecture
|
|
# specific options necessary for building the kernel and modules.
|
|
TARGET_CC_KERNEL_ARCH ?= ""
|
|
HOST_CC_KERNEL_ARCH ?= "${TARGET_CC_KERNEL_ARCH}"
|
|
TARGET_LD_KERNEL_ARCH ?= ""
|
|
HOST_LD_KERNEL_ARCH ?= "${TARGET_LD_KERNEL_ARCH}"
|
|
TARGET_AR_KERNEL_ARCH ?= ""
|
|
HOST_AR_KERNEL_ARCH ?= "${TARGET_AR_KERNEL_ARCH}"
|
|
TARGET_OBJCOPY_KERNEL_ARCH ?= ""
|
|
HOST_OBJCOPY_KERNEL_ARCH ?= "${TARGET_OBJCOPY_KERNEL_ARCH}"
|
|
TARGET_STRIP_KERNEL_ARCH ?= ""
|
|
HOST_STRIP_KERNEL_ARCH ?= "${TARGET_STRIP_KERNEL_ARCH}"
|
|
|
|
KERNEL_CC = "${CCACHE}${HOST_PREFIX}gcc ${HOST_CC_KERNEL_ARCH} -fuse-ld=bfd ${DEBUG_PREFIX_MAP} -fdebug-prefix-map=${STAGING_KERNEL_DIR}=${KERNEL_SRC_PATH} -fdebug-prefix-map=${STAGING_KERNEL_BUILDDIR}=${KERNEL_SRC_PATH}"
|
|
KERNEL_LD = "${CCACHE}${HOST_PREFIX}ld.bfd ${HOST_LD_KERNEL_ARCH}"
|
|
KERNEL_AR = "${CCACHE}${HOST_PREFIX}ar ${HOST_AR_KERNEL_ARCH}"
|
|
KERNEL_OBJCOPY = "${CCACHE}${HOST_PREFIX}objcopy ${HOST_OBJCOPY_KERNEL_ARCH}"
|
|
KERNEL_STRIP = "${CCACHE}${HOST_PREFIX}strip ${HOST_STRIP_KERNEL_ARCH}"
|
|
TOOLCHAIN ?= "gcc"
|
|
|
|
# 6.3+ requires the variable LOCALVERSION to be set to not get a "+" in
|
|
# the local version. Having it empty means nothing will be added, and any
|
|
# value will be appended to the local kernel version. This replaces the
|
|
# use of .scmversion file for setting a localversion without using
|
|
# the CONFIG_LOCALVERSION option.
|
|
KERNEL_LOCALVERSION ??= ""
|
|
export LOCALVERSION ?= "${KERNEL_LOCALVERSION}"
|