mirror of
https://git.yoctoproject.org/poky
synced 2026-02-05 16:28:43 +01:00
7abd40cd26
These two packages are required to ensure the manifest files contain all of the generated packages. Without this, the db and gdbm packages will not contain the .so files as they are skipped during the compilation steps (From OE-Core rev: 912c06615269f42230db2d93d70db2b340ed270a) Signed-off-by: Derek Straka <derek@asterius.io> Signed-off-by: Ross Burton <ross.burton@intel.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
86 lines
2.8 KiB
BlitzBasic
86 lines
2.8 KiB
BlitzBasic
require python.inc
|
|
EXTRANATIVEPATH += "bzip2-native"
|
|
DEPENDS = "openssl-native bzip2-replacement-native zlib-native readline-native sqlite3-native expat-native gdbm-native db-native"
|
|
PR = "${INC_PR}.1"
|
|
|
|
SRC_URI += "\
|
|
file://05-enable-ctypes-cross-build.patch \
|
|
file://10-distutils-fix-swig-parameter.patch \
|
|
file://11-distutils-never-modify-shebang-line.patch \
|
|
file://0001-distutils-set-the-prefix-to-be-inside-staging-direct.patch \
|
|
file://debug.patch \
|
|
file://unixccompiler.patch \
|
|
file://nohostlibs.patch \
|
|
file://multilib.patch \
|
|
file://add-md5module-support.patch \
|
|
file://builddir.patch \
|
|
file://parallel-makeinst-create-bindir.patch \
|
|
file://revert_use_of_sysconfigdata.patch \
|
|
"
|
|
|
|
S = "${WORKDIR}/Python-${PV}"
|
|
|
|
FILESEXTRAPATHS =. "${FILE_DIRNAME}/${PN}:"
|
|
|
|
inherit native
|
|
|
|
EXTRA_OECONF_append = " --bindir=${bindir}/${PN} --with-system-expat=${STAGING_DIR_HOST}"
|
|
|
|
EXTRA_OEMAKE = '\
|
|
LIBC="" \
|
|
STAGING_LIBDIR=${STAGING_LIBDIR_NATIVE} \
|
|
STAGING_INCDIR=${STAGING_INCDIR_NATIVE} \
|
|
'
|
|
|
|
do_configure_append() {
|
|
autoreconf --verbose --install --force --exclude=autopoint ../Python-${PV}/Modules/_ctypes/libffi
|
|
}
|
|
|
|
# Regenerate all of the generated files
|
|
# This ensures that pgen and friends get created during the compile phase
|
|
do_compile_prepend() {
|
|
oe_runmake regen-all
|
|
}
|
|
|
|
do_install() {
|
|
oe_runmake 'DESTDIR=${D}' install
|
|
install -d ${D}${bindir}/${PN}
|
|
install -m 0755 Parser/pgen ${D}${bindir}/${PN}
|
|
|
|
# Make sure we use /usr/bin/env python
|
|
for PYTHSCRIPT in `grep -rIl ${bindir}/${PN}/python ${D}${bindir}/${PN}`; do
|
|
sed -i -e '1s|^#!.*|#!/usr/bin/env python|' $PYTHSCRIPT
|
|
done
|
|
|
|
# Add a symlink to the native Python so that scripts can just invoke
|
|
# "nativepython" and get the right one without needing absolute paths
|
|
# (these often end up too long for the #! parser in the kernel as the
|
|
# buffer is 128 bytes long).
|
|
ln -s python-native/python ${D}${bindir}/nativepython
|
|
|
|
# We don't want modules in ~/.local being used in preference to those
|
|
# installed in the native sysroot, so disable user site support.
|
|
sed -i -e 's,^\(ENABLE_USER_SITE = \).*,\1False,' ${D}${libdir}/python${PYTHON_MAJMIN}/site.py
|
|
}
|
|
|
|
python(){
|
|
|
|
# Read JSON manifest
|
|
import json
|
|
pythondir = d.getVar('THISDIR',True)
|
|
with open(pythondir+'/python/python2-manifest.json') as manifest_file:
|
|
python_manifest=json.load(manifest_file)
|
|
|
|
rprovides = d.getVar('RPROVIDES').split()
|
|
|
|
# Hardcoded since it cant be python-native-foo, should be python-foo-native
|
|
pn = 'python'
|
|
|
|
for key in python_manifest:
|
|
pypackage = pn + '-' + key + '-native'
|
|
if pypackage not in rprovides:
|
|
rprovides.append(pypackage)
|
|
|
|
d.setVar('RPROVIDES', ' '.join(rprovides))
|
|
}
|