mirror of
https://git.yoctoproject.org/poky
synced 2026-09-24 22:36:21 +02:00
8511d1ec1b
As discussed on the mailing list, this variable isn't useful and if wanted would be better implemented by distros using pn-X overrides. This patch executes: find . -regex ".*\.\(bb\|inc\)$" | xargs sed -i '/^PRIORITY = ".*"$/d' against the tree removing the referenced. Thanks to Phil Blundell for the command. (From OE-Core rev: d122343362669c683acc4af295971a62cbc823fc) Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
53 lines
1.3 KiB
PHP
53 lines
1.3 KiB
PHP
DESCRIPTION = "U-boot bootloader"
|
|
HOMEPAGE = "http://u-boot.sf.net"
|
|
SECTION = "bootloaders"
|
|
PROVIDES = "virtual/bootloader"
|
|
|
|
inherit deploy
|
|
|
|
PARALLEL_MAKE=""
|
|
|
|
# GCC 4.5.1 builds unusable binaries using -Os, remove it from OPTFLAGS
|
|
EXTRA_OEMAKE = "CROSS_COMPILE=${TARGET_PREFIX} OPTFLAGS='-O2'"
|
|
|
|
python () {
|
|
if not d.getVar("UBOOT_MACHINE", True):
|
|
PN = d.getVar("PN", True)
|
|
FILE = os.path.basename(d.getVar("FILE", True))
|
|
bb.debug(1, "To build %s, see %s for instructions on \
|
|
setting up your machine config" % (PN, FILE))
|
|
raise bb.parse.SkipPackage("because UBOOT_MACHINE is not set")
|
|
}
|
|
|
|
UBOOT_IMAGE ?= "u-boot-${MACHINE}-${PV}-${PR}.bin"
|
|
UBOOT_BINARY ?= "u-boot.bin"
|
|
UBOOT_SYMLINK ?= "u-boot-${MACHINE}.bin"
|
|
UBOOT_MAKE_TARGET ?= "all"
|
|
|
|
do_compile () {
|
|
unset LDFLAGS
|
|
unset CFLAGS
|
|
unset CPPFLAGS
|
|
oe_runmake ${UBOOT_MACHINE}
|
|
oe_runmake ${UBOOT_MAKE_TARGET}
|
|
}
|
|
|
|
do_install () {
|
|
install -d ${D}/boot
|
|
install ${S}/${UBOOT_BINARY} ${D}/boot/${UBOOT_IMAGE}
|
|
ln -sf ${UBOOT_IMAGE} ${D}/boot/${UBOOT_BINARY}
|
|
}
|
|
|
|
FILES_${PN} = "/boot"
|
|
# no gnu_hash in uboot.bin, by design, so skip QA
|
|
INSANE_SKIP_${PN} = True
|
|
|
|
do_deploy () {
|
|
install ${S}/u-boot.bin ${DEPLOYDIR}/${UBOOT_IMAGE}
|
|
|
|
cd ${DEPLOYDIR}
|
|
rm -f ${UBOOT_SYMLINK}
|
|
ln -sf ${UBOOT_IMAGE} ${UBOOT_SYMLINK}
|
|
}
|
|
addtask deploy before do_build after do_compile
|