mirror of
https://git.yoctoproject.org/poky
synced 2026-02-28 04:19:40 +01:00
864c0f5269
Integrating the warning/leak fixes: 73873cb152c brd: remove unused brd_mutex 912c53b1b346 audit: fix memleak in auditd_send_unicast_skb. (From OE-Core rev: 4aec8f304216d5427f22d4a72f9f39be097513cb) (From OE-Core rev: bc6310b704dd7dcbd865ee8f09ce0f7b4326497c) Signed-off-by: Bruce Ashfield <bruce.ashfield@windriver.com> Signed-off-by: Ross Burton <ross.burton@intel.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org> Signed-off-by: Armin Kuster <akuster808@gmail.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
39 lines
1.4 KiB
BlitzBasic
39 lines
1.4 KiB
BlitzBasic
KBRANCH ?= "standard/preempt-rt/base"
|
|
|
|
require recipes-kernel/linux/linux-yocto.inc
|
|
|
|
# Skip processing of this recipe if it is not explicitly specified as the
|
|
# PREFERRED_PROVIDER for virtual/kernel. This avoids errors when trying
|
|
# to build multiple virtual/kernel providers, e.g. as dependency of
|
|
# core-image-rt-sdk, core-image-rt.
|
|
python () {
|
|
if d.getVar("PREFERRED_PROVIDER_virtual/kernel") != "linux-yocto-rt":
|
|
raise bb.parse.SkipPackage("Set PREFERRED_PROVIDER_virtual/kernel to linux-yocto-rt to enable it")
|
|
}
|
|
|
|
SRCREV_machine ?= "27c21aed67a28d08b13c5cc1fe4287b2cf389ede"
|
|
SRCREV_meta ?= "6d6037cc054350140df49c309e155f5a7b48f480"
|
|
|
|
SRC_URI = "git://git.yoctoproject.org/linux-yocto-4.12.git;branch=${KBRANCH};name=machine \
|
|
git://git.yoctoproject.org/yocto-kernel-cache;type=kmeta;name=meta;branch=yocto-4.12;destsuffix=${KMETA}"
|
|
|
|
LINUX_VERSION ?= "4.12.20"
|
|
|
|
PV = "${LINUX_VERSION}+git${SRCPV}"
|
|
|
|
KMETA = "kernel-meta"
|
|
KCONF_BSP_AUDIT_LEVEL = "2"
|
|
|
|
LINUX_KERNEL_TYPE = "preempt-rt"
|
|
|
|
COMPATIBLE_MACHINE = "(qemux86|qemux86-64|qemuarm|qemuppc|qemumips)"
|
|
|
|
KERNEL_DEVICETREE_qemuarm = "versatile-pb.dtb"
|
|
|
|
# Functionality flags
|
|
KERNEL_EXTRA_FEATURES ?= "features/netfilter/netfilter.scc features/taskstats/taskstats.scc"
|
|
KERNEL_FEATURES_append = " ${KERNEL_EXTRA_FEATURES}"
|
|
KERNEL_FEATURES_append_qemuall=" cfg/virtio.scc"
|
|
KERNEL_FEATURES_append_qemux86=" cfg/sound.scc cfg/paravirt_kvm.scc"
|
|
KERNEL_FEATURES_append_qemux86-64=" cfg/sound.scc"
|