mirror of
https://git.yoctoproject.org/poky
synced 2026-04-30 03:32:12 +02:00
53caeebc71
The licence checksum is modified according to the change of doc/LICENCE. In specific, file://lib/util/reallocarray.c is added to LIC_FILES_CHECKSUM. Fix out of tree builds, and explicitly enable/disable tmpfiles.d support based on the systemd DISTRO_FEATURE to avoid non-deterministic packaging. Based on a patch by Chen Qi <Qi.Chen@windriver.com> (From OE-Core rev: ef2a842d06b3a9ee6036af06247c7c022f8c720d) Signed-off-by: Ross Burton <ross.burton@intel.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
35 lines
1.4 KiB
BlitzBasic
35 lines
1.4 KiB
BlitzBasic
require sudo.inc
|
|
|
|
SRC_URI = "http://ftp.sudo.ws/sudo/dist/sudo-${PV}.tar.gz \
|
|
${@bb.utils.contains('DISTRO_FEATURES', 'pam', '${PAM_SRC_URI}', '', d)} \
|
|
file://0001-Use-correct-path-to-init.d-and-tmpfiles.d-files.patch \
|
|
"
|
|
|
|
PAM_SRC_URI = "file://sudo.pam"
|
|
|
|
SRC_URI[md5sum] = "93dbd1e47c136179ff1b01494c1c0e75"
|
|
SRC_URI[sha256sum] = "a8a697cbb113859058944850d098464618254804cf97961dee926429f00a1237"
|
|
|
|
DEPENDS += " ${@bb.utils.contains('DISTRO_FEATURES', 'pam', 'libpam', '', d)}"
|
|
RDEPENDS_${PN} += " ${@bb.utils.contains('DISTRO_FEATURES', 'pam', 'pam-plugin-limits pam-plugin-keyinit', '', d)}"
|
|
|
|
EXTRA_OECONF += " \
|
|
${@bb.utils.contains('DISTRO_FEATURES', 'pam', '--with-pam', '--without-pam', d)} \
|
|
${@bb.utils.contains('DISTRO_FEATURES', 'systemd', '--enable-tmpfiles.d=${libdir}/tmpfiles.d', '--disable-tmpfiles.d', d)} \
|
|
"
|
|
|
|
do_install_append () {
|
|
if [ "${@bb.utils.contains('DISTRO_FEATURES', 'pam', 'pam', '', d)}" = "pam" ]; then
|
|
install -D -m 664 ${WORKDIR}/sudo.pam ${D}/${sysconfdir}/pam.d/sudo
|
|
fi
|
|
|
|
chmod 4111 ${D}${bindir}/sudo
|
|
chmod 0440 ${D}${sysconfdir}/sudoers
|
|
|
|
# Explicitly remove the ${localstatedir}/run directory to avoid QA error
|
|
rmdir -p --ignore-fail-on-non-empty ${D}${localstatedir}/run/sudo
|
|
}
|
|
|
|
FILES_${PN} += "${libdir}/tmpfiles.d"
|
|
FILES_${PN}-dev += "${libdir}/${BPN}/lib*${SOLIBSDEV} ${libdir}/${BPN}/*.la"
|