mirror of
https://git.yoctoproject.org/poky
synced 2026-02-24 18:39:40 +01:00
1c28cf571a
If the OS is not Linux, the code could end up generating a recursive symlink. This can happen because the same symlink can be created twice in a row. If this happenes, the second symlink becomes a link to itself within the directory pointed to by the original link. In order to prevent this, verify that the destination does not already exist. (From OE-Core rev: ef28e5a74d939acc98d6e8e9a0efbeb143b8025f) Signed-off-by: Mark Hatle <mark.hatle@xilinx.com> Signed-off-by: Mark Hatle <mark.hatle@kernel.crashing.org> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
54 lines
1.7 KiB
PHP
54 lines
1.7 KiB
PHP
require libgcc-common.inc
|
|
|
|
DEPENDS = "virtual/${TARGET_PREFIX}gcc virtual/${TARGET_PREFIX}g++ virtual/${MLPREFIX}libc"
|
|
|
|
do_install_append_class-target () {
|
|
if [ "${TCLIBC}" != "glibc" ]; then
|
|
case "${TARGET_OS}" in
|
|
"linux-musl" | "linux-*spe") extra_target_os="linux";;
|
|
"linux-musleabi") extra_target_os="linux-gnueabi";;
|
|
*) extra_target_os="linux";;
|
|
esac
|
|
if [ ! -e ${D}${libdir}/${TARGET_ARCH}${TARGET_VENDOR}-$extra_target_os ]; then
|
|
ln -s ${TARGET_SYS} ${D}${libdir}/${TARGET_ARCH}${TARGET_VENDOR}-$extra_target_os
|
|
fi
|
|
fi
|
|
if [ -n "${@ bb.utils.contains('TUNE_CCARGS_MFLOAT', 'hard', 'hf', '', d)}" ]; then
|
|
case "${TARGET_OS}" in
|
|
"linux-musleabi") extra_target_os="linux-musleabihf";;
|
|
"linux-gnueabi") extra_target_os="linux-gnueabihf";;
|
|
esac
|
|
if [ ! -e ${D}${libdir}/${TARGET_ARCH}${TARGET_VENDOR}-$extra_target_os ]; then
|
|
ln -s ${TARGET_SYS} ${D}${libdir}/${TARGET_ARCH}${TARGET_VENDOR}-$extra_target_os
|
|
fi
|
|
fi
|
|
}
|
|
|
|
PACKAGES = "\
|
|
${PN} \
|
|
${PN}-dev \
|
|
${PN}-dbg \
|
|
"
|
|
|
|
# All libgcc source is marked with the exception.
|
|
#
|
|
LICENSE_${PN} = "GPL-3.0-with-GCC-exception"
|
|
LICENSE_${PN}-dev = "GPL-3.0-with-GCC-exception"
|
|
LICENSE_${PN}-dbg = "GPL-3.0-with-GCC-exception"
|
|
|
|
|
|
FILES_${PN}-dev = "\
|
|
${base_libdir}/libgcc*.so \
|
|
${@oe.utils.conditional('BASETARGET_SYS', '${TARGET_SYS}', '', '${libdir}/${BASETARGET_SYS}', d)} \
|
|
${libdir}/${TARGET_SYS}/${BINV}* \
|
|
${libdir}/${TARGET_ARCH}${TARGET_VENDOR}* \
|
|
"
|
|
|
|
do_package[depends] += "virtual/${MLPREFIX}libc:do_packagedata"
|
|
do_package_write_ipk[depends] += "virtual/${MLPREFIX}libc:do_packagedata"
|
|
do_package_write_deb[depends] += "virtual/${MLPREFIX}libc:do_packagedata"
|
|
do_package_write_rpm[depends] += "virtual/${MLPREFIX}libc:do_packagedata"
|
|
|
|
INSANE_SKIP_${PN}-dev = "staticdev"
|
|
|