mirror of
https://git.yoctoproject.org/poky
synced 2026-03-14 19:29:41 +01:00
3a80fde534
Integrating the following commit(s) to linux-yocto/5.15: Author: Bruce Ashfield <bruce.ashfield@gmail.com> Date: Sun Jul 10 22:56:53 2022 -0400 lib/build_OID_registry: fix reproducibility issues The script build_OID_registry captures the full path of itself in the generated data. This causes reproduciblity issues as the path is captured and packaged. We use the basename of the script instead, and that allows us to be reprodicible, with slightly less information captured in the output data (but the generating script can still easily be found). (From OE-Core rev: 708421238ed149b1eabf463bd563a37480ad1169) Signed-off-by: Bruce Ashfield <bruce.ashfield@gmail.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
71 lines
3.4 KiB
BlitzBasic
71 lines
3.4 KiB
BlitzBasic
KBRANCH ?= "v5.15/standard/base"
|
|
|
|
require recipes-kernel/linux/linux-yocto.inc
|
|
|
|
# board specific branches
|
|
KBRANCH:qemuarm ?= "v5.15/standard/arm-versatile-926ejs"
|
|
KBRANCH:qemuarm64 ?= "v5.15/standard/qemuarm64"
|
|
KBRANCH:qemumips ?= "v5.15/standard/mti-malta32"
|
|
KBRANCH:qemuppc ?= "v5.15/standard/qemuppc"
|
|
KBRANCH:qemuriscv64 ?= "v5.15/standard/base"
|
|
KBRANCH:qemuriscv32 ?= "v5.15/standard/base"
|
|
KBRANCH:qemux86 ?= "v5.15/standard/base"
|
|
KBRANCH:qemux86-64 ?= "v5.15/standard/base"
|
|
KBRANCH:qemumips64 ?= "v5.15/standard/mti-malta64"
|
|
|
|
SRCREV_machine:qemuarm ?= "3d2ffe77f277a0a650e7d012c5bfe3765a467e4b"
|
|
SRCREV_machine:qemuarm64 ?= "1da6524b1508ca6e9b6602471b478d310bec1960"
|
|
SRCREV_machine:qemumips ?= "4101fd448319edc00fec2bd822be407d19205bb9"
|
|
SRCREV_machine:qemuppc ?= "651a0112fb207bae1be0d2609e9a910135fb4feb"
|
|
SRCREV_machine:qemuriscv64 ?= "2fca0fd719812ea2ff67630b01355aa80481623e"
|
|
SRCREV_machine:qemuriscv32 ?= "2fca0fd719812ea2ff67630b01355aa80481623e"
|
|
SRCREV_machine:qemux86 ?= "2fca0fd719812ea2ff67630b01355aa80481623e"
|
|
SRCREV_machine:qemux86-64 ?= "2fca0fd719812ea2ff67630b01355aa80481623e"
|
|
SRCREV_machine:qemumips64 ?= "d518b9a80c938ca7ce11e56d2275c33b89dfc9c3"
|
|
SRCREV_machine ?= "2fca0fd719812ea2ff67630b01355aa80481623e"
|
|
SRCREV_meta ?= "f122fe59e74365eba84bae800898ffd7329c628d"
|
|
|
|
# set your preferred provider of linux-yocto to 'linux-yocto-upstream', and you'll
|
|
# get the <version>/base branch, which is pure upstream -stable, and the same
|
|
# meta SRCREV as the linux-yocto-standard builds. Select your version using the
|
|
# normal PREFERRED_VERSION settings.
|
|
BBCLASSEXTEND = "devupstream:target"
|
|
SRCREV_machine:class-devupstream ?= "545aecd229613138d6db54fb2b5221faca10137f"
|
|
PN:class-devupstream = "linux-yocto-upstream"
|
|
KBRANCH:class-devupstream = "v5.15/base"
|
|
|
|
SRC_URI = "git://git.yoctoproject.org/linux-yocto.git;name=machine;branch=${KBRANCH}; \
|
|
git://git.yoctoproject.org/yocto-kernel-cache;type=kmeta;name=meta;branch=yocto-5.15;destsuffix=${KMETA}"
|
|
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=6bc538ed5bd9a7fc9398086aedcd7e46"
|
|
LINUX_VERSION ?= "5.15.52"
|
|
|
|
DEPENDS += "${@bb.utils.contains('ARCH', 'x86', 'elfutils-native', '', d)}"
|
|
DEPENDS += "openssl-native util-linux-native"
|
|
DEPENDS += "gmp-native libmpc-native"
|
|
|
|
PV = "${LINUX_VERSION}+git${SRCPV}"
|
|
|
|
KMETA = "kernel-meta"
|
|
KCONF_BSP_AUDIT_LEVEL = "1"
|
|
|
|
KERNEL_DEVICETREE:qemuarmv5 = "versatile-pb.dtb"
|
|
|
|
COMPATIBLE_MACHINE = "qemuarm|qemuarmv5|qemuarm64|qemux86|qemuppc|qemuppc64|qemumips|qemumips64|qemux86-64|qemuriscv64|qemuriscv32"
|
|
|
|
# Functionality flags
|
|
KERNEL_EXTRA_FEATURES ?= "features/netfilter/netfilter.scc"
|
|
KERNEL_FEATURES:append = " ${KERNEL_EXTRA_FEATURES}"
|
|
KERNEL_FEATURES:append:qemuall=" cfg/virtio.scc features/drm-bochs/drm-bochs.scc"
|
|
KERNEL_FEATURES:append:qemux86=" cfg/sound.scc cfg/paravirt_kvm.scc"
|
|
KERNEL_FEATURES:append:qemux86-64=" cfg/sound.scc cfg/paravirt_kvm.scc"
|
|
KERNEL_FEATURES:append = " ${@bb.utils.contains("TUNE_FEATURES", "mx32", " cfg/x32.scc", "", d)}"
|
|
KERNEL_FEATURES:append = " ${@bb.utils.contains("DISTRO_FEATURES", "ptest", " features/scsi/scsi-debug.scc", "", d)}"
|
|
KERNEL_FEATURES:append = " ${@bb.utils.contains("DISTRO_FEATURES", "ptest", " features/gpio/mockup.scc", "", d)}"
|
|
KERNEL_FEATURES:append:powerpc =" arch/powerpc/powerpc-debug.scc"
|
|
KERNEL_FEATURES:append:powerpc64 =" arch/powerpc/powerpc-debug.scc"
|
|
KERNEL_FEATURES:append:powerpc64le =" arch/powerpc/powerpc-debug.scc"
|
|
|
|
INSANE_SKIP:kernel-vmlinux:qemuppc64 = "textrel"
|
|
|