mirror of
https://git.yoctoproject.org/poky
synced 2026-02-20 08:29:42 +01:00
87a19bbc3c
Fixes: [YOCTO #13471] (From OE-Core rev: 54e0df20665be8df9d8961d8c4e716e38104ba16) Signed-off-by: Ida Delphine <idadelm@gmail.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org> (cherry picked from commit 6db24928d62aeb093a0e6da6619713eaca57a96f) Signed-off-by: Steve Sakoman <steve@sakoman.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
74 lines
2.7 KiB
BlitzBasic
74 lines
2.7 KiB
BlitzBasic
SUMMARY = "Small library that defines common error values for all GnuPG components"
|
|
DESCRIPTION = "Contains common error codes and error handling functions used by GnuPG, Libgcrypt, GPGME and more packages. "
|
|
HOMEPAGE = "http://www.gnupg.org/related_software/libgpg-error/"
|
|
BUGTRACKER = "https://bugs.g10code.com/gnupg/index"
|
|
|
|
LICENSE = "GPLv2+ & LGPLv2.1+"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=59530bdf33659b29e73d4adb9f9f6552 \
|
|
file://COPYING.LIB;md5=2d5025d4aa3495befef8f17206a5b0a1 \
|
|
file://src/gpg-error.h.in;beginline=2;endline=18;md5=cd91e3ad1265a0c268efad541a39345e \
|
|
file://src/init.c;beginline=2;endline=17;md5=f01cdfcf747af5380590cfd9bbfeaaf7"
|
|
|
|
|
|
SECTION = "libs"
|
|
|
|
UPSTREAM_CHECK_URI = "https://gnupg.org/download/index.html"
|
|
SRC_URI = "${GNUPG_MIRROR}/libgpg-error/libgpg-error-${PV}.tar.bz2 \
|
|
file://pkgconfig.patch \
|
|
file://0001-Do-not-fail-when-testing-config-scripts.patch \
|
|
"
|
|
|
|
SRC_URI[md5sum] = "729f22d917494fdc4b54fce5aa6547c7"
|
|
SRC_URI[sha256sum] = "b32d6ff72a73cf79797f7f2d039e95e9c6f92f0c1450215410840ab62aea9763"
|
|
|
|
BINCONFIG = "${bindir}/gpg-error-config"
|
|
|
|
inherit autotools binconfig-disabled pkgconfig gettext multilib_header multilib_script
|
|
|
|
MULTILIB_SCRIPTS = "${PN}-dev:${bindir}/gpgrt-config"
|
|
|
|
CPPFLAGS += "-P"
|
|
do_compile_prepend() {
|
|
TARGET_FILE=linux-gnu
|
|
if [ ${TARGET_OS} = "mingw32" ]; then
|
|
# There are no arch specific syscfg files for mingw32
|
|
TARGET_FILE=
|
|
elif [ ${TARGET_ARCH} = "arc" ]; then
|
|
# ARC syscfg file is automatically aliased to i686-pc-linux-gnu
|
|
TARGET_FILE=
|
|
elif [ ${TARGET_OS} != "linux" ]; then
|
|
TARGET_FILE=${TARGET_OS}
|
|
fi
|
|
|
|
case ${TARGET_ARCH} in
|
|
aarch64_be) TUPLE=aarch64-unknown-linux-gnu ;;
|
|
arm) TUPLE=arm-unknown-linux-gnueabi ;;
|
|
armeb) TUPLE=arm-unknown-linux-gnueabi ;;
|
|
i586|i686) TUPLE=i686-unknown-linux-gnu;;
|
|
mips64*) TUPLE=mips64el-unknown-linux-gnuabi64 ;;
|
|
mips*el) TUPLE=mipsel-unknown-linux-gnu ;;
|
|
mips*) TUPLE=mips-unknown-linux-gnu ;;
|
|
x86_64) TUPLE=x86_64-unknown-linux-gnu ;;
|
|
ppc) TUPLE=powerpc-unknown-linux-gnu ;;
|
|
ppc64) TUPLE=powerpc64-unknown-linux-gnu ;;
|
|
ppc64le) TUPLE=powerpc64le-unknown-linux-gnu ;;
|
|
*) TUPLE=${TARGET_ARCH}-unknown-linux-gnu ;;
|
|
esac
|
|
|
|
if [ -n "$TARGET_FILE" ]; then
|
|
cp ${S}/src/syscfg/lock-obj-pub.$TUPLE.h \
|
|
${S}/src/syscfg/lock-obj-pub.$TARGET_FILE.h
|
|
fi
|
|
}
|
|
|
|
do_install_append() {
|
|
# we don't have common lisp in OE
|
|
rm -rf "${D}${datadir}/common-lisp/"
|
|
oe_multilib_header gpg-error.h gpgrt.h
|
|
}
|
|
|
|
FILES_${PN}-dev += "${bindir}/gpg-error"
|
|
FILES_${PN}-doc += "${datadir}/libgpg-error/errorref.txt"
|
|
|
|
BBCLASSEXTEND = "native nativesdk"
|