mirrors/poky
1
0
Fork 0
mirror of https://git.yoctoproject.org/poky synced 2026-04-30 21:32:13 +02:00
Code Issues Packages Projects Releases Wiki Activity
Files
8e57e88f9dba1cffa683343025cfbdcdcededdbc
poky/meta/recipes-extended/tzdata/tzdata_2016g.bb
Armin Kuster 0cbd843501 tzdata: update to 2016g 
LICENSE md5sum changed do to rewording some text not released to the license.
see 8c143a2b65

  Changes to future time stamps

    Turkey switched from EET/EEST (+02/+03) to permanent +03,
    effective 2016-09-07.  (Thanks to Burak AYDIN.)  Use "+03" rather
    than an invented abbreviation for the new time.

    New leap second 2016-12-31 23:59:60 UTC as per IERS Bulletin C 52.
    (Thanks to Tim Parenti.)

  Changes to past time stamps

    For America/Los_Angeles, spring-forward transition times have been
    corrected from 02:00 to 02:01 in 1948, and from 02:00 to 01:00 in
    1950-1966.

    For zones using Soviet time on 1919-07-01, transitions to UT-based
    time were at 00:00 UT, not at 02:00 local time.  The affected
    zones are Europe/Kirov, Europe/Moscow, Europe/Samara, and
    Europe/Ulyanovsk.  (Thanks to Alexander Belopolsky.)

  Changes to past and future time zone abbreviations

    The Factory zone now uses the time zone abbreviation -00 instead
    of a long English-language string, as -00 is now the normal way to
    represent an undefined time zone.

    Several zones in Antarctica and the former Soviet Union, along
    with zones intended for ships at sea that cannot use POSIX TZ
    strings, now use numeric time zone abbreviations instead of
    invented or obsolete alphanumeric abbreviations.  The affected
    zones are Antarctica/Casey, Antarctica/Davis,
    Antarctica/DumontDUrville, Antarctica/Mawson, Antarctica/Rothera,
    Antarctica/Syowa, Antarctica/Troll, Antarctica/Vostok,
    Asia/Anadyr, Asia/Ashgabat, Asia/Baku, Asia/Bishkek, Asia/Chita,
    Asia/Dushanbe, Asia/Irkutsk, Asia/Kamchatka, Asia/Khandyga,
    Asia/Krasnoyarsk, Asia/Magadan, Asia/Omsk, Asia/Sakhalin,
    Asia/Samarkand, Asia/Srednekolymsk, Asia/Tashkent, Asia/Tbilisi,
    Asia/Ust-Nera, Asia/Vladivostok, Asia/Yakutsk, Asia/Yekaterinburg,
    Asia/Yerevan, Etc/GMT-14, Etc/GMT-13, Etc/GMT-12, Etc/GMT-11,
    Etc/GMT-10, Etc/GMT-9, Etc/GMT-8, Etc/GMT-7, Etc/GMT-6, Etc/GMT-5,
    Etc/GMT-4, Etc/GMT-3, Etc/GMT-2, Etc/GMT-1, Etc/GMT+1, Etc/GMT+2,
    Etc/GMT+3, Etc/GMT+4, Etc/GMT+5, Etc/GMT+6, Etc/GMT+7, Etc/GMT+8,
    Etc/GMT+9, Etc/GMT+10, Etc/GMT+11, Etc/GMT+12, Europe/Kaliningrad,
    Europe/Minsk, Europe/Samara, Europe/Volgograd, and
    Indian/Kerguelen.  For Europe/Moscow the invented abbreviation MSM
    was replaced by +05, whereas MSK and MSD were kept as they are not
    our invention and are widely used.

  Changes to zone names

    Rename Asia/Rangoon to Asia/Yangon, with a backward compatibility link.
    (Thanks to David Massoud.)

(From OE-Core rev: d1341aeda6d9fa5d7f13afabadae60a6fc295b87)

Signed-off-by: Armin Kuster <akuster@mvista.com>
Signed-off-by: Ross Burton <ross.burton@intel.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
2016-10-01 21:45:55 +01:00

214 lines
8.9 KiB
BlitzBasic
Raw Blame History

SUMMARY = "Timezone data"
HOMEPAGE = "http://www.iana.org/time-zones"
SECTION = "base"
LICENSE = "PD & BSD & BSD-3-Clause"
LIC_FILES_CHKSUM = "file://LICENSE;md5=ef1a352b901ee7b75a75df8171d6aca7"
DEPENDS = "tzcode-native"
SRC_URI = "http://www.iana.org/time-zones/repository/releases/tzdata${PV}.tar.gz;name=tzdata"
UPSTREAM_CHECK_URI = "http://www.iana.org/time-zones"
SRC_URI[tzdata.md5sum] = "3c7e97ec8527211104d27cc1d97a23de"
SRC_URI[tzdata.sha256sum] = "3c7137b2bc47323b0de47b77786bacf81ed503d4b2c693ff8ada2fbd1281ebd1"
inherit allarch
RCONFLICTS_${PN} = "timezones timezone-africa timezone-america timezone-antarctica \
timezone-arctic timezone-asia timezone-atlantic \
timezone-australia timezone-europe timezone-indian \
timezone-iso3166.tab timezone-pacific timezone-zone.tab"
S = "${WORKDIR}"
DEFAULT_TIMEZONE ?= "Universal"
INSTALL_TIMEZONE_FILE ?= "1"
TZONES= "africa antarctica asia australasia europe northamerica southamerica \
factory etcetera backward systemv \
"
# pacificnew
do_compile () {
for zone in ${TZONES}; do \
${STAGING_BINDIR_NATIVE}/zic -d ${WORKDIR}${datadir}/zoneinfo -L /dev/null \
-y ${S}/yearistype.sh ${S}/${zone} ; \
${STAGING_BINDIR_NATIVE}/zic -d ${WORKDIR}${datadir}/zoneinfo/posix -L /dev/null \
-y ${S}/yearistype.sh ${S}/${zone} ; \
${STAGING_BINDIR_NATIVE}/zic -d ${WORKDIR}${datadir}/zoneinfo/right -L ${S}/leapseconds \
-y ${S}/yearistype.sh ${S}/${zone} ; \
done
}
do_install () {
install -d ${D}/$exec_prefix ${D}${datadir}/zoneinfo
cp -pPR ${S}/$exec_prefix ${D}/
# libc is removing zoneinfo files from package
cp -pP "${S}/zone.tab" ${D}${datadir}/zoneinfo
cp -pP "${S}/iso3166.tab" ${D}${datadir}/zoneinfo
# Install default timezone
if [ -e ${D}${datadir}/zoneinfo/${DEFAULT_TIMEZONE} ]; then
install -d ${D}${sysconfdir}
if [ "${INSTALL_TIMEZONE_FILE}" = "1" ]; then
echo ${DEFAULT_TIMEZONE} > ${D}${sysconfdir}/timezone
fi
ln -s ${datadir}/zoneinfo/${DEFAULT_TIMEZONE} ${D}${sysconfdir}/localtime
else
bberror "DEFAULT_TIMEZONE is set to an invalid value."
exit 1
fi
chown -R root:root ${D}
}
pkg_postinst_${PN} () {
etc_lt="$D${sysconfdir}/localtime"
src="$D${sysconfdir}/timezone"
if [ -e ${src} ] ; then
tz=$(sed -e 's:#.*::' -e 's:[[:space:]]*::g' -e '/^$/d' "${src}")
fi
if [ -z "${tz}" ] ; then
exit 0
fi
if [ ! -e "$D${datadir}/zoneinfo/${tz}" ] ; then
echo "You have an invalid TIMEZONE setting in ${src}"
echo "Your ${etc_lt} has been reset to Universal; enjoy!"
tz="Universal"
echo "Updating ${etc_lt} with $D${datadir}/zoneinfo/${tz}"
if [ -L ${etc_lt} ] ; then
rm -f "${etc_lt}"
fi
ln -s "${datadir}/zoneinfo/${tz}" "${etc_lt}"
fi
}
# Packages primarily organized by directory with a major city
# in most time zones in the base package
PACKAGES = "tzdata tzdata-misc tzdata-posix tzdata-right tzdata-africa \
tzdata-americas tzdata-antarctica tzdata-arctic tzdata-asia \
tzdata-atlantic tzdata-australia tzdata-europe tzdata-pacific"
FILES_tzdata-africa += "${datadir}/zoneinfo/Africa/*"
RPROVIDES_tzdata-africa = "tzdata-africa"
FILES_tzdata-americas += "${datadir}/zoneinfo/America/* \
${datadir}/zoneinfo/US/* \
${datadir}/zoneinfo/Brazil/* \
${datadir}/zoneinfo/Canada/* \
${datadir}/zoneinfo/Mexico/* \
${datadir}/zoneinfo/Chile/*"
RPROVIDES_tzdata-americas = "tzdata-americas"
FILES_tzdata-antarctica += "${datadir}/zoneinfo/Antarctica/*"
RPROVIDES_tzdata-antarctica = "tzdata-antarctica"
FILES_tzdata-arctic += "${datadir}/zoneinfo/Arctic/*"
RPROVIDES_tzdata-arctic = "tzdata-arctic"
FILES_tzdata-asia += "${datadir}/zoneinfo/Asia/* \
${datadir}/zoneinfo/Indian/* \
${datadir}/zoneinfo/Mideast/*"
RPROVIDES_tzdata-asia = "tzdata-asia"
FILES_tzdata-atlantic += "${datadir}/zoneinfo/Atlantic/*"
RPROVIDES_tzdata-atlantic = "tzdata-atlantic"
FILES_tzdata-australia += "${datadir}/zoneinfo/Australia/*"
RPROVIDES_tzdata-australia = "tzdata-australia"
FILES_tzdata-europe += "${datadir}/zoneinfo/Europe/*"
RPROVIDES_tzdata-europe = "tzdata-europe"
FILES_tzdata-pacific += "${datadir}/zoneinfo/Pacific/*"
RPROVIDES_tzdata-pacific = "tzdata-pacific"
FILES_tzdata-posix += "${datadir}/zoneinfo/posix/*"
RPROVIDES_tzdata-posix = "tzdata-posix"
FILES_tzdata-right += "${datadir}/zoneinfo/right/*"
RPROVIDES_tzdata-right = "tzdata-right"
FILES_tzdata-misc += "${datadir}/zoneinfo/Cuba \
${datadir}/zoneinfo/Egypt \
${datadir}/zoneinfo/Eire \
${datadir}/zoneinfo/Factory \
${datadir}/zoneinfo/GB-Eire \
${datadir}/zoneinfo/Hongkong \
${datadir}/zoneinfo/Iceland \
${datadir}/zoneinfo/Iran \
${datadir}/zoneinfo/Israel \
${datadir}/zoneinfo/Jamaica \
${datadir}/zoneinfo/Japan \
${datadir}/zoneinfo/Kwajalein \
${datadir}/zoneinfo/Libya \
${datadir}/zoneinfo/Navajo \
${datadir}/zoneinfo/Poland \
${datadir}/zoneinfo/Portugal \
${datadir}/zoneinfo/Singapore \
${datadir}/zoneinfo/Turkey"
RPROVIDES_tzdata-misc = "tzdata-misc"
FILES_${PN} += "${datadir}/zoneinfo/Pacific/Honolulu \
${datadir}/zoneinfo/America/Anchorage \
${datadir}/zoneinfo/America/Los_Angeles \
${datadir}/zoneinfo/America/Denver \
${datadir}/zoneinfo/America/Chicago \
${datadir}/zoneinfo/America/New_York \
${datadir}/zoneinfo/America/Caracas \
${datadir}/zoneinfo/America/Sao_Paulo \
${datadir}/zoneinfo/Europe/London \
${datadir}/zoneinfo/Europe/Paris \
${datadir}/zoneinfo/Africa/Cairo \
${datadir}/zoneinfo/Europe/Moscow \
${datadir}/zoneinfo/Asia/Dubai \
${datadir}/zoneinfo/Asia/Karachi \
${datadir}/zoneinfo/Asia/Dhaka \
${datadir}/zoneinfo/Asia/Bankok \
${datadir}/zoneinfo/Asia/Hong_Kong \
${datadir}/zoneinfo/Asia/Tokyo \
${datadir}/zoneinfo/Australia/Darwin \
${datadir}/zoneinfo/Australia/Adelaide \
${datadir}/zoneinfo/Australia/Brisbane \
${datadir}/zoneinfo/Australia/Sydney \
${datadir}/zoneinfo/Pacific/Noumea \
${datadir}/zoneinfo/CET \
${datadir}/zoneinfo/CST6CDT \
${datadir}/zoneinfo/EET \
${datadir}/zoneinfo/EST \
${datadir}/zoneinfo/EST5EDT \
${datadir}/zoneinfo/GB \
${datadir}/zoneinfo/GMT \
${datadir}/zoneinfo/GMT+0 \
${datadir}/zoneinfo/GMT-0 \
${datadir}/zoneinfo/GMT0 \
${datadir}/zoneinfo/Greenwich \
${datadir}/zoneinfo/HST \
${datadir}/zoneinfo/MET \
${datadir}/zoneinfo/MST \
${datadir}/zoneinfo/MST7MDT \
${datadir}/zoneinfo/NZ \
${datadir}/zoneinfo/NZ-CHAT \
${datadir}/zoneinfo/PRC \
${datadir}/zoneinfo/PST8PDT \
${datadir}/zoneinfo/ROC \
${datadir}/zoneinfo/ROK \
${datadir}/zoneinfo/UCT \
${datadir}/zoneinfo/UTC \
${datadir}/zoneinfo/Universal \
${datadir}/zoneinfo/W-SU \
${datadir}/zoneinfo/WET \
${datadir}/zoneinfo/Zulu \
${datadir}/zoneinfo/zone.tab \
${datadir}/zoneinfo/iso3166.tab \
${datadir}/zoneinfo/Etc/*"
CONFFILES_${PN} += "${@ "${sysconfdir}/timezone" if bb.utils.to_boolean(d.getVar('INSTALL_TIMEZONE_FILE', True)) else "" }"
CONFFILES_${PN} += "${sysconfdir}/localtime"
Reference in New Issue View Git Blame Copy Permalink