mirror of
https://git.yoctoproject.org/poky
synced 2026-04-26 18:32:13 +02:00
63dd6190cb
Use upstream systemd service files instead of our own service files. This also makes sure that /run/rpcbind.sock is used which fixes the following systemd warning: /usr/lib/systemd/system/rpcbind.socket:5: ListenStream= references a path below legacy directory /var/run/, updating /var/run/rpcbind.sock \xe2\x86\x92 /run/rpcbind.sock; please update the unit file accordingly. (From OE-Core rev: ad08385393bb0d072f2f27f5a189041037e06195) Signed-off-by: Stefan Agner <stefan.agner@toradex.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
53 lines
2.0 KiB
BlitzBasic
53 lines
2.0 KiB
BlitzBasic
SUMMARY = "Universal Addresses to RPC Program Number Mapper"
|
|
DESCRIPTION = "The rpcbind utility is a server that converts RPC \
|
|
program numbers into universal addresses."
|
|
SECTION = "console/network"
|
|
HOMEPAGE = "http://sourceforge.net/projects/rpcbind/"
|
|
BUGTRACKER = "http://sourceforge.net/tracker/?group_id=201237&atid=976751"
|
|
DEPENDS = "libtirpc quota"
|
|
|
|
LICENSE = "BSD-3-Clause"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=b46486e4c4a416602693a711bb5bfa39 \
|
|
file://src/rpcinfo.c;beginline=1;endline=27;md5=f8a8cd2cb25ac5aa16767364fb0e3c24"
|
|
|
|
SRC_URI = "${SOURCEFORGE_MIRROR}/rpcbind/rpcbind-${PV}.tar.bz2 \
|
|
file://init.d \
|
|
file://rpcbind.conf \
|
|
file://rpcbind_add_option_to_fix_port_number.patch \
|
|
file://0001-systemd-use-EnvironmentFile.patch \
|
|
"
|
|
SRC_URI[md5sum] = "ed46f09b9c0fa2d49015f6431bc5ea7b"
|
|
SRC_URI[sha256sum] = "2ce360683963b35c19c43f0ee2c7f18aa5b81ef41c3fdbd15ffcb00b8bffda7a"
|
|
|
|
inherit autotools update-rc.d systemd pkgconfig
|
|
|
|
PACKAGECONFIG ??= "tcp-wrappers"
|
|
PACKAGECONFIG[tcp-wrappers] = "--enable-libwrap,--disable-libwrap,tcp-wrappers"
|
|
|
|
INITSCRIPT_NAME = "rpcbind"
|
|
INITSCRIPT_PARAMS = "start 12 2 3 4 5 . stop 60 0 1 6 ."
|
|
|
|
SYSTEMD_SERVICE_${PN} = "rpcbind.service rpcbind.socket"
|
|
|
|
inherit useradd
|
|
|
|
USERADD_PACKAGES = "${PN}"
|
|
USERADD_PARAM_${PN} = "--system --no-create-home --home-dir / \
|
|
--shell /bin/false --user-group rpc"
|
|
|
|
PACKAGECONFIG ??= "${@bb.utils.filter('DISTRO_FEATURES', 'systemd', d)}"
|
|
PACKAGECONFIG[systemd] = "--with-systemdsystemunitdir=${systemd_unitdir}/system/, \
|
|
--without-systemdsystemunitdir, \
|
|
systemd \
|
|
"
|
|
|
|
EXTRA_OECONF += " --enable-warmstarts --with-rpcuser=rpc"
|
|
|
|
do_install_append () {
|
|
install -d ${D}${sysconfdir}/init.d
|
|
sed -e 's,/etc/,${sysconfdir}/,g' \
|
|
-e 's,/sbin/,${sbindir}/,g' \
|
|
${WORKDIR}/init.d > ${D}${sysconfdir}/init.d/rpcbind
|
|
chmod 0755 ${D}${sysconfdir}/init.d/rpcbind
|
|
}
|