mirror of
https://git.yoctoproject.org/poky
synced 2026-04-30 03:32:12 +02:00
b350ef0cea
Stop creating the static library archive(liba(ttr|cl).a) when --disable-static configure option used. (From OE-Core rev: 2c84649139059b810f28babe9d8d82035fde19ee) Signed-off-by: Amarnath Valluri <amarnath.valluri@intel.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
53 lines
1.9 KiB
PHP
53 lines
1.9 KiB
PHP
# this build system is mostly shared by attr and acl
|
|
|
|
SRC_URI += "file://relative-libdir.patch;striplevel=0 \
|
|
"
|
|
# This patch should be applied after '(attr\|acl)-Missing-configure.ac.patch'
|
|
SRC_URI_append = " file://0001-Added-configure-option-to-enable-disable-static-libr.patch"
|
|
|
|
inherit autotools-brokensep gettext
|
|
|
|
# the package comes with a custom config.h.in, it cannot be
|
|
# overwritten by autoheader
|
|
EXTRA_AUTORECONF += "--exclude=autoheader"
|
|
EXTRA_OECONF = "INSTALL_USER=root INSTALL_GROUP=root"
|
|
EXTRA_OECONF_append_class-native = " --enable-gettext=no"
|
|
EXTRA_OECONF_append_class-target = "${@['', ' --disable-gettext '][(d.getVar('USE_NLS') == 'no')]}"
|
|
|
|
EXTRA_OEMAKE = "PKG_LIB_DIR=${base_libdir} PKG_DEVLIB_DIR=${libdir}"
|
|
|
|
do_install () {
|
|
oe_runmake install install-lib install-dev DIST_ROOT="${D}"
|
|
}
|
|
|
|
do_install_append_class-native () {
|
|
if test "${libdir}" = "${base_libdir}" ; then
|
|
return
|
|
fi
|
|
librelpath=${@os.path.relpath(d.getVar('libdir'), d.getVar('base_libdir'))}
|
|
baselibrelpath=${@os.path.relpath(d.getVar('base_libdir'), d.getVar('libdir'))}
|
|
|
|
# Remove bad symlinks & create the correct symlinks
|
|
if test -L ${D}${libdir}/lib${BPN}.so ; then
|
|
rm -rf ${D}${libdir}/lib${BPN}.so
|
|
ln -sf $baselibrelpath/lib${BPN}.so ${D}${libdir}/lib${BPN}.so
|
|
fi
|
|
if test -L ${D}${base_libdir}/lib${BPN}.a ; then
|
|
rm -rf ${D}${base_libdir}/lib${BPN}.a
|
|
ln -sf $librelpath/lib${BPN}.a ${D}${base_libdir}/lib${BPN}.a
|
|
fi
|
|
if test -L ${D}${base_libdir}/lib${BPN}.la ; then
|
|
rm -rf ${D}${base_libdir}/lib${BPN}.la
|
|
ln -sf $librelpath/lib${BPN}.la ${D}${base_libdir}/lib${BPN}.la
|
|
fi
|
|
}
|
|
|
|
PACKAGES =+ "lib${BPN}"
|
|
|
|
FILES_lib${BPN} = "${base_libdir}/lib*${SOLIBS}"
|
|
|
|
BBCLASSEXTEND = "native"
|
|
# Only append ldflags for target recipe and if USE_NLS is enabled
|
|
LDFLAGS_append_libc-uclibc_class-target = "${@['', ' -lintl '][(d.getVar('USE_NLS') == 'yes')]}"
|
|
EXTRA_OECONF_append_libc-uclibc_class-target = "${@['', ' --disable-gettext '][(d.getVar('USE_NLS') == 'no')]}"
|