mirror of
https://git.yoctoproject.org/poky
synced 2026-02-08 01:36:38 +01:00
994783b52e
This changeset fixes a feature regression in ubiformat. Older versions of ubiformat, when invoked with a flash-image, would return 0 in the case no error was encountered. Upon upgrading to latest, it was discovered that ubiformat returned 255 even without encountering an error condition. This changeset corrects the above issue and causes ubiformat, when given an image file, to return 0 when no errors are detected. Backport fix from 2.1.2 (From OE-Core rev: 3ee98b6c9ddd1dd0825245ca672236b7befb9859) Signed-off-by: Otavio Salvador <otavio@ossystems.com.br> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org> (cherry picked from commit 7ebacd9cbaec98fbc406e8ae99c9805a24fdadc6) Signed-off-by: Steve Sakoman <steve@sakoman.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
80 lines
3.6 KiB
BlitzBasic
80 lines
3.6 KiB
BlitzBasic
SUMMARY = "Tools for managing memory technology devices"
|
|
HOMEPAGE = "http://www.linux-mtd.infradead.org/"
|
|
SECTION = "base"
|
|
LICENSE = "GPLv2+"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=0636e73ff0215e8d672dc4c32c317bb3 \
|
|
file://include/common.h;beginline=1;endline=17;md5=ba05b07912a44ea2bf81ce409380049c"
|
|
|
|
inherit autotools pkgconfig update-alternatives
|
|
|
|
DEPENDS = "zlib e2fsprogs util-linux"
|
|
RDEPENDS_mtd-utils-tests += "bash"
|
|
|
|
PV = "2.1.1"
|
|
|
|
SRCREV = "4443221ce9b88440cd9f5bb78e6fe95621d36c8a"
|
|
SRC_URI = "git://git.infradead.org/mtd-utils.git \
|
|
file://add-exclusion-to-mkfs-jffs2-git-2.patch \
|
|
file://0001-mtd-utils-Fix-return-value-of-ubiformat.patch \
|
|
"
|
|
|
|
S = "${WORKDIR}/git/"
|
|
|
|
EXTRA_OECONF += "--enable-install-tests"
|
|
|
|
# xattr support creates an additional compile-time dependency on acl because
|
|
# the sys/acl.h header is needed. libacl is not needed and thus enabling xattr
|
|
# regardless whether acl is enabled or disabled in the distro should be okay.
|
|
PACKAGECONFIG ??= "${@bb.utils.filter('DISTRO_FEATURES', 'xattr', d)} lzo jffs ubifs"
|
|
PACKAGECONFIG[lzo] = "--with-lzo,--without-lzo,lzo"
|
|
PACKAGECONFIG[xattr] = "--with-xattr,--without-xattr,acl"
|
|
PACKAGECONFIG[crypto] = "--with-crypto,--without-crypto,openssl"
|
|
PACKAGECONFIG[jffs] = "--with-jffs,--without-jffs"
|
|
PACKAGECONFIG[ubifs] = "--with-ubifs,--without-ubifs"
|
|
PACKAGECONFIG[zstd] = "--with-zstd,--without-zstd,zstd"
|
|
|
|
CPPFLAGS_append_riscv64 = " -pthread -D_REENTRANT"
|
|
|
|
EXTRA_OEMAKE = "'CC=${CC}' 'RANLIB=${RANLIB}' 'AR=${AR}' 'CFLAGS=${CFLAGS} ${@bb.utils.contains('PACKAGECONFIG', 'xattr', '', '-DWITHOUT_XATTR', d)} -I${S}/include' 'BUILDDIR=${S}'"
|
|
|
|
# Use higher priority than corresponding BusyBox-provided applets
|
|
ALTERNATIVE_PRIORITY = "100"
|
|
|
|
ALTERNATIVE_${PN} = "flashcp flash_eraseall flash_lock flash_unlock nanddump nandwrite"
|
|
ALTERNATIVE_${PN}-ubifs = "ubiattach ubidetach ubimkvol ubirename ubirmvol ubirsvol ubiupdatevol"
|
|
|
|
ALTERNATIVE_LINK_NAME[flash_eraseall] = "${sbindir}/flash_eraseall"
|
|
ALTERNATIVE_LINK_NAME[nandwrite] = "${sbindir}/nandwrite"
|
|
ALTERNATIVE_LINK_NAME[nanddump] = "${sbindir}/nanddump"
|
|
ALTERNATIVE_LINK_NAME[ubiattach] = "${sbindir}/ubiattach"
|
|
ALTERNATIVE_LINK_NAME[ubiattach] = "${sbindir}/ubiattach"
|
|
ALTERNATIVE_LINK_NAME[ubidetach] = "${sbindir}/ubidetach"
|
|
ALTERNATIVE_LINK_NAME[ubimkvol] = "${sbindir}/ubimkvol"
|
|
ALTERNATIVE_LINK_NAME[ubirename] = "${sbindir}/ubirename"
|
|
ALTERNATIVE_LINK_NAME[ubirmvol] = "${sbindir}/ubirmvol"
|
|
ALTERNATIVE_LINK_NAME[ubirsvol] = "${sbindir}/ubirsvol"
|
|
ALTERNATIVE_LINK_NAME[ubiupdatevol] = "${sbindir}/ubiupdatevol"
|
|
ALTERNATIVE_LINK_NAME[flash_eraseall] = "${sbindir}/flash_eraseall"
|
|
ALTERNATIVE_LINK_NAME[flash_lock] = "${sbindir}/flash_lock"
|
|
ALTERNATIVE_LINK_NAME[flash_unlock] = "${sbindir}/flash_unlock"
|
|
ALTERNATIVE_LINK_NAME[flashcp] = "${sbindir}/flashcp"
|
|
|
|
do_install () {
|
|
oe_runmake install DESTDIR=${D} SBINDIR=${sbindir} MANDIR=${mandir} INCLUDEDIR=${includedir}
|
|
}
|
|
|
|
PACKAGES =+ "mtd-utils-misc mtd-utils-tests"
|
|
PACKAGES =+ "${@bb.utils.contains("PACKAGECONFIG", "jffs", "mtd-utils-jffs2", "", d)}"
|
|
PACKAGES =+ "${@bb.utils.contains("PACKAGECONFIG", "ubifs", "mtd-utils-ubifs", "", d)}"
|
|
|
|
FILES_mtd-utils-jffs2 = "${sbindir}/mkfs.jffs2 ${sbindir}/jffs2dump ${sbindir}/jffs2reader ${sbindir}/sumtool"
|
|
FILES_mtd-utils-ubifs = "${sbindir}/mkfs.ubifs ${sbindir}/ubi*"
|
|
FILES_mtd-utils-misc = "${sbindir}/nftl* ${sbindir}/ftl* ${sbindir}/rfd* ${sbindir}/doc* ${sbindir}/serve_image ${sbindir}/recv_image"
|
|
FILES_mtd-utils-tests = "${libexecdir}/mtd-utils/*"
|
|
|
|
BBCLASSEXTEND = "native nativesdk"
|
|
|
|
# git/.compr.c.dep:46: warning: NUL character seen; rest of line ignored
|
|
# git/.compr.c.dep:47: *** missing separator. Stop.
|
|
PARALLEL_MAKE = ""
|