mirror of
https://git.yoctoproject.org/poky
synced 2026-05-02 18:32:15 +02:00
f19e8de4cf
In 2ce514a394e1e062172bb097aa92a1792a0f8eaf, "coreutils: fix ALTERNATIVE_PRIORITY conflict with procps and mktemp" the priority was lowered from 100 to 30. Unfortunately this lowered coreutils past busybox which means busybox was ending up in our SDK images. This isn't what users expect. 1c0cfffee21e99a7356c9046c86628bc0acf654c raises the priority of mktemp to 200, do the same for procps and make the system consistent. (From OE-Core rev: 770618eb33fc576f903a4c8011cc2d9f8f78071d) Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
68 lines
2.6 KiB
BlitzBasic
68 lines
2.6 KiB
BlitzBasic
SUMMARY = "System and process monitoring utilities"
|
|
DESCRIPTION = "Procps contains a set of system utilities that provide system information about processes using \
|
|
the /proc filesystem. The package includes the programs ps, top, vmstat, w, kill, and skill."
|
|
HOMEPAGE = "https://gitorious.org/procps"
|
|
SECTION = "base"
|
|
LICENSE = "GPLv2+ & LGPLv2+"
|
|
LIC_FILES_CHKSUM="file://COPYING;md5=b234ee4d69f5fce4486a80fdaf4a4263 \
|
|
file://COPYING.LIB;md5=4cf66a4984120007c9881cc871cf49db \
|
|
"
|
|
|
|
DEPENDS = "ncurses"
|
|
|
|
inherit autotools gettext pkgconfig update-alternatives
|
|
|
|
SRC_URI = "http://downloads.sourceforge.net/project/procps-ng/Production/procps-ng-${PV}.tar.xz \
|
|
file://fix-configure.patch \
|
|
file://sysctl.conf \
|
|
"
|
|
|
|
SRC_URI[md5sum] = "1fb7f3f6bf92ce6c5c9ed9949ae858fe"
|
|
SRC_URI[sha256sum] = "a02e6f98974dfceab79884df902ca3df30b0e9bad6d76aee0fb5dce17f267f04"
|
|
|
|
S = "${WORKDIR}/procps-ng-${PV}"
|
|
|
|
EXTRA_OECONF = "--enable-skill --disable-modern-top"
|
|
|
|
CPPFLAGS += "-I${S}"
|
|
|
|
do_install_append () {
|
|
install -d ${D}${base_bindir}
|
|
[ "${bindir}" != "${base_bindir}" ] && for i in ${base_bindir_progs}; do mv ${D}${bindir}/$i ${D}${base_bindir}/$i; done
|
|
install -d ${D}${base_sbindir}
|
|
[ "${sbindir}" != "${base_sbindir}" ] && for i in ${base_sbindir_progs}; do mv ${D}${sbindir}/$i ${D}${base_sbindir}/$i; done
|
|
if [ "${base_sbindir}" != "${sbindir}" ]; then
|
|
rmdir ${D}${sbindir}
|
|
fi
|
|
|
|
install -d ${D}${sysconfdir}
|
|
install -m 0644 ${WORKDIR}/sysctl.conf ${D}${sysconfdir}/sysctl.conf
|
|
if ${@bb.utils.contains('DISTRO_FEATURES','systemd','true','false',d)}; then
|
|
install -d ${D}${sysconfdir}/sysctl.d
|
|
ln -sf ../sysctl.conf ${D}${sysconfdir}/sysctl.d/99-sysctl.conf
|
|
fi
|
|
}
|
|
|
|
CONFFILES_${PN} = "${sysconfdir}/sysctl.conf"
|
|
|
|
bindir_progs = "free pkill pmap pgrep pwdx skill snice top uptime"
|
|
base_bindir_progs += "kill pidof ps watch"
|
|
base_sbindir_progs += "sysctl"
|
|
|
|
ALTERNATIVE_PRIORITY = "200"
|
|
|
|
ALTERNATIVE_${PN} = "${bindir_progs} ${base_bindir_progs} ${base_sbindir_progs}"
|
|
|
|
ALTERNATIVE_${PN}-doc = "kill.1 uptime.1"
|
|
ALTERNATIVE_LINK_NAME[kill.1] = "${mandir}/man1/kill.1"
|
|
ALTERNATIVE_LINK_NAME[uptime.1] = "${mandir}/man1/uptime.1"
|
|
|
|
python __anonymous() {
|
|
for prog in d.getVar('base_bindir_progs', True).split():
|
|
d.setVarFlag('ALTERNATIVE_LINK_NAME', prog, '%s/%s' % (d.getVar('base_bindir', True), prog))
|
|
|
|
for prog in d.getVar('base_sbindir_progs', True).split():
|
|
d.setVarFlag('ALTERNATIVE_LINK_NAME', prog, '%s/%s' % (d.getVar('base_sbindir', True), prog))
|
|
}
|
|
|