mirror of
https://git.yoctoproject.org/poky
synced 2026-04-04 14:02:22 +02:00
95bfdce73d
Some of the SYSLINUX defaults are the same as in the underlying syslinux.bbclass. Let's not duplicate them, because that makes changing the default harder. (From OE-Core rev: 7418709450e428010545dc9943802dd64c9582e1) Signed-off-by: Patrick Ohly <patrick.ohly@intel.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
45 lines
1.5 KiB
Plaintext
45 lines
1.5 KiB
Plaintext
|
|
SYSLINUX_PROMPT ?= "0"
|
|
SYSLINUX_LABELS = "boot"
|
|
LABELS_append = " ${SYSLINUX_LABELS} "
|
|
|
|
# need to define the dependency and the ROOTFS for directdisk
|
|
do_bootdirectdisk[depends] += "${PN}:do_rootfs"
|
|
ROOTFS ?= "${DEPLOY_DIR_IMAGE}/${IMAGE_BASENAME}-${MACHINE}.ext4"
|
|
|
|
# creating VM images relies on having a hddimg so ensure we inherit it here.
|
|
inherit boot-directdisk
|
|
|
|
IMAGE_TYPEDEP_vmdk = "ext4"
|
|
IMAGE_TYPEDEP_vdi = "ext4"
|
|
IMAGE_TYPEDEP_qcow2 = "ext4"
|
|
IMAGE_TYPES_MASKED += "vmdk vdi qcow2"
|
|
|
|
create_vmdk_image () {
|
|
qemu-img convert -O vmdk ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.hdddirect ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.vmdk
|
|
ln -sf ${IMAGE_NAME}.vmdk ${DEPLOY_DIR_IMAGE}/${IMAGE_LINK_NAME}.vmdk
|
|
}
|
|
|
|
create_vdi_image () {
|
|
qemu-img convert -O vdi ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.hdddirect ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.vdi
|
|
ln -sf ${IMAGE_NAME}.vdi ${DEPLOY_DIR_IMAGE}/${IMAGE_LINK_NAME}.vdi
|
|
}
|
|
|
|
create_qcow2_image () {
|
|
qemu-img convert -O qcow2 ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.hdddirect ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.qcow2
|
|
ln -sf ${IMAGE_NAME}.qcow2 ${DEPLOY_DIR_IMAGE}/${IMAGE_LINK_NAME}.qcow2
|
|
}
|
|
|
|
python do_vmimg() {
|
|
if 'vmdk' in d.getVar('IMAGE_FSTYPES', True):
|
|
bb.build.exec_func('create_vmdk_image', d)
|
|
if 'vdi' in d.getVar('IMAGE_FSTYPES', True):
|
|
bb.build.exec_func('create_vdi_image', d)
|
|
if 'qcow2' in d.getVar('IMAGE_FSTYPES', True):
|
|
bb.build.exec_func('create_qcow2_image', d)
|
|
}
|
|
|
|
addtask vmimg after do_bootdirectdisk before do_build
|
|
do_vmimg[depends] += "qemu-native:do_populate_sysroot"
|
|
|